• 取消检验批过账（取消检验批UD判定到Rerel，再把非限性库存转到质检库存，然后就可以取101收货了）

    直接取消101收货时，出现以下提示：

     

    （1）第一种方法：先把主数据的QM视图的QM相关信息取消，如下图：

      

    取消QM采购激活及检验设置后，通过传输过账，把数量从非限库存转到质检库存。

    过账完成后，数量从非限定到质检。再过SE16N把删除检验批与物料凭证的关联关系(记得在查询前在命令窗口输入/h,再回车):

     

    然后，选中，删除，保存即可。

    再取消101收货即可，

     

     （2）第二种方法，就打Notes(SAP Notes 74638).通过检验批取消UD转到为Rerel（zqevac40）。再通过检验批把非限定性库存转为质检库存（zrqevac50）。

    对用户来讲，只需输入事务码：ZMMXX8 （可以把权限直接给仓库主管即可），然后输入检验批，执行即可以。

    执行完成后，直接 MIGO,取消相应的物料凭证即可。

     具体代码如下：

     以下代码调用两步（UD转REREL\非限定库存转质检库存），可以定一个事务码：ZMMXX8，程序ZQMR_CANCEL_Q。

    1. *&---------------------------------------------------------------------*
    2. *& Report  ZQMR_CANCEL_Q
    3. *&
    4. *&---------------------------------------------------------------------*
    5. *&
    6. *&
    7. *&---------------------------------------------------------------------*
    8.  
    9. REPORT ZQMR_CANCEL_Q.
    10.  
    11. PARAMETERS:
    12.   prueflos LIKE qals-prueflos OBLIGATORY MEMORY ID qls.
    13.  
    14. START-OF-SELECTION.
    15.  
    16.   SUBMIT zqevac40 WITH prueflos = prueflos AND RETURN.
    17.  
    18.   WAIT UP TO 1 SECONDS.
    19.  
    20.   SUBMIT zrqevac50 WITH prueflos = prueflos AND RETURN.

     取消检验批UD转rerel，代码如下：

    1. *&---------------------------------------------------------------------*
    2. *& Report  ZQEVAC40
    3. *&
    4. *&---------------------------------------------------------------------*
    5. *&
    6. *&
    7. *&---------------------------------------------------------------------*
    8. REPORT zqevac40.
    9. *----------------------------------------------------------------------*
    10. *  Datendefinitionen
    11. *----------------------------------------------------------------------*
    12. * Tabellen
    13. *----------------------------------------------------------------------*
    14. TABLES sscrfields.
    15. TABLES qals.
    16. TABLES qave.
    17.  
    18. *----------------------------------------------------------------------*
    19. * Konstanten
    20. CONSTANTS:
    21.   c_rc_0  LIKE sy-subrc           VALUE 0,
    22.   c_rc_4  LIKE sy-subrc           VALUE 4,
    23.   c_rc_20 LIKE sy-subrc           VALUE 20,
    24. *
    25.   c_kreuz LIKE qm00-qkz           VALUE 'X'.
    26. *
    27.  
    28. *----------------------------------------------------------------------*
    29. * Eingabebildschirm
    30. SELECTION-SCREEN SKIP 2.
    31. PARAMETERS prueflos  LIKE qals-prueflos MATCHCODE OBJECT qals
    32.                                         MEMORY ID qls .
    33. SELECTION-SCREEN SKIP 1.
    34. SELECTION-SCREEN BEGIN OF BLOCK search WITH FRAME.
    35. SELECTION-SCREEN BEGIN OF LINE.
    36.  
    37. SELECTION-SCREEN PUSHBUTTON 3(20) TEXT-s01 USER-COMMAND sear.
    38. SELECTION-SCREEN PUSHBUTTON 40(20) TEXT-s02 USER-COMMAND show.
    39.  
    40. SELECTION-SCREEN END OF LINE.
    41. SELECTION-SCREEN END OF BLOCK search.
    42.  
    43.  
    44.  
    45. *----------------------------------------------------------------------*
    46. AT SELECTION-SCREEN.
    47.  
    48.  
    49.  
    50.  
    51.  
    52.  
    53.   IF sscrfields-ucomm EQ 'SEAR'
    54.     OR prueflos IS INITIAL.
    55.     CALL FUNCTION 'QELA_START_SELECTION_OF_LOTS'
    56.       EXPORTING
    57.         i_selid          = ' '
    58.         i_stat_aenderung = 'X'
    59.         i_stat_ero       = 'X'
    60.         i_stat_frei      = 'X'
    61.         i_stat_ve        = ' '
    62.       IMPORTING
    63.         e_prueflos       = prueflos
    64.       EXCEPTIONS
    65.         no_entry         = 1
    66.         no_selected      = 2
    67.         OTHERS           = 3.
    68.   ENDIF.
    69.  
    70.  
    71.   IF sscrfields-ucomm EQ 'SHOW'.
    72.     CALL FUNCTION 'QSS1_LOT_SHOW'
    73.       EXPORTING
    74.         i_prueflos = prueflos.
    75.   ENDIF.
    76.  
    77.   CHECK sscrfields-ucomm EQ 'ONLI'.
    78.  
    79. * ab hier mu　Pr黤losnummer gef黮lt sein.
    80.   IF prueflos IS INITIAL.
    81.     MESSAGE e164(qa).
    82.   ENDIF.
    83.  
    84. * Lesen Los
    85.   CALL FUNCTION 'ENQUEUE_EQQALS1'
    86.     EXPORTING
    87.       prueflos = prueflos.
    88.  
    89.   CALL FUNCTION 'QPSE_LOT_READ'
    90.     EXPORTING
    91.       i_prueflos = prueflos
    92.     IMPORTING
    93.       e_qals     = qals
    94.     EXCEPTIONS
    95.       no_lot     = 1.
    96.   IF NOT sy-subrc IS INITIAL.
    97.     MESSAGE e102(qa).
    98.   ENDIF.
    99. *-----------------
    100. * Pr黤en Status
    101.   CALL FUNCTION 'QAST_STATUS_CHECK'
    102.     EXPORTING
    103.       i_objnr          = qals-objnr
    104.       i_status         = 'I0218' "Status VE getroffen
    105.     EXCEPTIONS
    106.       status_not_activ = 1.
    107.   IF NOT sy-subrc IS INITIAL.
    108.     MESSAGE e102(qv) WITH qals-prueflos.
    109.   ENDIF.
    110. *
    111.   CALL FUNCTION 'QEVA_UD_READ'
    112.     EXPORTING
    113.       i_prueflos = qals-prueflos
    114.     IMPORTING
    115.       e_qave     = qave.
    116.  
    117.  
    118. *---------------------------------------------------------------------*
    119. START-OF-SELECTION.
    120. * Vorgaben sind ok.   1. Material Umlagern und Los 鋘dern
    121.  
    122.   PERFORM qals_aendern.
    123. ************************************************************************
    124. *----------------------------------------------------------------------*
    125. *       FORM QALS_aendern
    126. *----------------------------------------------------------------------*
    127. FORM qals_aendern.
    128. *
    129.   PERFORM status_fix_setzen USING 'I0002' c_kreuz.
    130.   PERFORM status_fix_setzen USING 'I0216' space.
    131.   PERFORM status_fix_setzen USING 'I0217' space.
    132.   PERFORM status_fix_setzen USING 'I0218' space.
    133.   CLEAR: qals-stat14.
    134.   CLEAR: qals-stat35.
    135.   CLEAR: qave-vauswahlmg,
    136.        qave-vwerks,
    137.        qave-versionam,
    138.        qave-vcodegrp,
    139.        qave-vcode,
    140.        qave-vbewertung,
    141.        qave-versioncd,
    142.        qave-vfolgeakti,
    143.        qave-qkennzahl.
    144. *--... verbuchen
    145.   CALL FUNCTION 'QEVA_UD_UPDATE' IN UPDATE TASK
    146.     EXPORTING
    147.       qals_new = qals
    148.       qave_new = qave.
    149.   COMMIT WORK.
    150.   MESSAGE s101(qa) WITH qals-prueflos.
    151.   CALL FUNCTION 'DEQUEUE_EQQALS1'
    152.     EXPORTING
    153.       prueflos = prueflos.
    154. ENDFORM.                    "qals_aendern
    155. *----------------------------------------------------------------------*
    156. *       Form  STATUS_FIX_SETZEN
    157. *----------------------------------------------------------------------*
    158. *   Setzen eines Status aufgrund von Voreinstellungen wie QMAT etc.    *
    159. *----------------------------------------------------------------------*
    160. *  -->  STATUS    Status der gesetzt werden soll
    161. *  -->  AKTIV     Status wird aktiviert sonst deaktiviert
    162. *----------------------------------------------------------------------*
    163. FORM status_fix_setzen USING
    164.             VALUE(status) LIKE tj02-istat
    165.             VALUE(aktiv) LIKE c_kreuz.
    166. * lokale Tabelle fuer Statusfortschreibung
    167.   DATA: BEGIN OF l_stattab OCCURS 0.
    168.       INCLUDE STRUCTURE jstat.
    169.   DATA  END OF l_stattab.
    170. *
    171. * Falls Objektnr. nicht gef黮lt. --> Fehlermeldung !!!
    172.   IF qals-objnr EQ space.
    173.     MESSAGE e013(qv).
    174. *   Fehlende Objektnr.: Problem f　script>document.write('\r\n');
    175.   ENDIF.
    176.   MOVE status TO l_stattab-stat.
    177.   IF aktiv EQ space.
    178.     MOVE c_kreuz TO l_stattab-inact.
    179.   ENDIF.
    180. *
    181.   APPEND l_stattab.
    182. *
    183.   CALL FUNCTION 'STATUS_CHANGE_INTERN'
    184.     EXPORTING
    185.       check_only = space
    186.       objnr      = qals-objnr
    187.     TABLES
    188.       status     = l_stattab.
    189.  
    190. ENDFORM.                               " STATUS_FIX_SETZEN

    把非限定性库存转质检库存代码如下：

    1.  
    2. *&---------------------------------------------------------------------*
    3. *& Report  ZRQEVAC50
    4. *&
    5. *&---------------------------------------------------------------------*
    6. *&
    7. *&
    8. *&---------------------------------------------------------------------*
    9. REPORT zrqevac50 MESSAGE-ID qa.
    10.  
    11. TYPES:
    12.   t_mkpf_tab LIKE mkpf  OCCURS 0,
    13.   t_mseg_tab LIKE mseg  OCCURS 0.
    14.  
    15. PARAMETERS:
    16.   prueflos LIKE qals-prueflos OBLIGATORY MEMORY ID qls.
    17.  
    18. DATA:
    19.   g_msgv1       LIKE sy-msgv1,
    20.   g_qals        LIKE qals,
    21.   g_qals_leiste LIKE qals,
    22.   g_qamb_tab    TYPE qambtab,
    23.   g_qamb_vb_tab TYPE qambtab,
    24.   g_mkpf_tab    TYPE t_mkpf_tab,
    25.   g_mseg_tab    TYPE t_mseg_tab,
    26.   g_subrc       LIKE sy-subrc.
    27.  
    28.  
    29. START-OF-SELECTION.
    30.  
    31.   PERFORM enqueue_qals USING prueflos
    32.                              g_subrc.
    33.   IF NOT g_subrc IS INITIAL.
    34.     MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
    35.             WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    36.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    37.   ENDIF.
    38.  
    39.   PERFORM read_qals USING prueflos
    40.                           g_qals
    41.                           g_qals_leiste
    42.                           g_subrc.
    43.   IF NOT g_subrc IS INITIAL.
    44.     MESSAGE ID 'QA' TYPE 'S' NUMBER '102'
    45.             WITH prueflos.
    46.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    47.   ENDIF.
    48.  
    49.   PERFORM check_lot USING g_qals
    50.                           g_subrc.
    51.   IF NOT g_subrc IS INITIAL.
    52.     CASE g_subrc.
    53.       WHEN 256.
    54.         g_msgv1 = 'Lot & does not refer to a material doc'.
    55.       WHEN 128.
    56.         g_msgv1 = 'Material & is serialized'.
    57.         REPLACE '&' WITH g_qals-matnr INTO g_msgv1.
    58.       WHEN  64.
    59.         g_msgv1 = 'Lot & is not stock relevant'.
    60.       WHEN  32.
    61.         g_msgv1 = 'Lot &: No stock transferred'.
    62.       WHEN  16.
    63.         g_msgv1 = 'Lot & is cancelled'.
    64.       WHEN   8.
    65.         g_msgv1 = 'Lot & is archived'.
    66.       WHEN   4.
    67.         g_msgv1 = 'Lot & is blocked'.
    68.       WHEN   2.
    69.         g_msgv1 = 'Lot & is HU managed'.
    70.     ENDCASE.
    71.     REPLACE '&' WITH prueflos INTO g_msgv1.
    72.     MESSAGE ID '00' TYPE 'S' NUMBER '208'
    73.             WITH g_msgv1.
    74.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    75.   ENDIF.
    76.  
    77.   PERFORM read_qamb USING g_qals
    78.                           g_qamb_tab
    79.                           g_subrc.
    80.   IF NOT g_subrc IS INITIAL.
    81.     MESSAGE ID 'QA' TYPE 'S' NUMBER '068'
    82.             WITH prueflos.
    83.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    84.   ENDIF.
    85.  
    86.   PERFORM read_mkpf USING g_qamb_tab
    87.                           g_mkpf_tab
    88.                           g_subrc.
    89.   IF NOT g_subrc IS INITIAL.
    90.     MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
    91.             WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    92.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    93.   ENDIF.
    94.  
    95.   PERFORM check_mkpf USING g_mkpf_tab
    96.                            g_subrc.
    97.   IF NOT g_subrc IS INITIAL.
    98.     MESSAGE ID 'QA' TYPE 'S' NUMBER '068'
    99.             WITH prueflos.
    100.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    101.   ENDIF.
    102.  
    103.   PERFORM read_mseg USING g_mkpf_tab
    104.                           g_mseg_tab
    105.                           g_subrc.
    106.   IF NOT g_subrc IS INITIAL.
    107.     MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
    108.             WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    109.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    110.   ENDIF.
    111.  
    112.   PERFORM check_mseg USING g_mseg_tab
    113.                            g_qamb_tab
    114.                            g_subrc.
    115.   IF NOT g_subrc IS INITIAL.
    116.     MESSAGE ID 'QA' TYPE 'S' NUMBER '068'
    117.             WITH prueflos.
    118.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    119.   ENDIF.
    120.  
    121.   PERFORM create_goods_movement USING g_qals
    122.                                       g_mseg_tab
    123.                                       g_subrc.
    124.  
    125.   IF NOT g_subrc IS INITIAL.
    126.     MESSAGE ID 'QA' TYPE 'S' NUMBER '068'
    127.             WITH prueflos.
    128.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    129.   ENDIF.
    130.  
    131.   PERFORM post_goods_movement.
    132.  
    133.   PERFORM post_data USING g_qals
    134.                           g_qals_leiste
    135.                           g_qamb_tab
    136.                           g_qamb_vb_tab
    137.                           g_subrc.
    138.  
    139.   IF NOT g_subrc IS INITIAL.
    140.     MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
    141.             WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    142.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    143.   ELSE.
    144.     COMMIT WORK AND WAIT.
    145.     g_msgv1 = 'inspection lot &'.
    146.     REPLACE '&' WITH prueflos INTO g_msgv1.
    147.     MESSAGE ID '00' TYPE 'S' NUMBER '368'
    148.             WITH 'Stock posting reversed for ' g_msgv1.
    149. *    SUBMIT (SY-REPID) VIA SELECTION-SCREEN.
    150.   ENDIF.
    151.  
    152. *----------------------------------------------------------------------*
    153. *       Form  ENQUEUE_QALS                                             *
    154. *----------------------------------------------------------------------*
    155. *       Los sperren                                                    *
    156. *----------------------------------------------------------------------*
    157. FORM enqueue_qals USING p_prueflos LIKE qals-prueflos
    158.                         p_subrc    LIKE sy-subrc.
    159.   CLEAR: p_subrc.
    160.  
    161.   CALL FUNCTION 'ENQUEUE_EQQALS1'
    162.     EXPORTING
    163.       prueflos       = p_prueflos
    164.     EXCEPTIONS
    165.       foreign_lock   = 1
    166.       system_failure = 2
    167.       OTHERS         = 3.
    168.  
    169.   p_subrc = sy-subrc.
    170.  
    171. ENDFORM.                               " ENQUEUE_QALS
    172.  
    173. *----------------------------------------------------------------------*
    174. *       Form  READ_QALS                                                *
    175. *----------------------------------------------------------------------*
    176. *       Pr黤los lesen                                                  *
    177. *----------------------------------------------------------------------*
    178. FORM read_qals USING p_prueflos    LIKE qals-prueflos
    179.                      p_qals        LIKE qals
    180.                      p_qals_leiste LIKE qals
    181.                      p_subrc       LIKE sy-subrc.
    182.  
    183.   CLEAR: p_subrc.
    184.  
    185.   CALL FUNCTION 'QPSE_LOT_READ'
    186.     EXPORTING
    187.       i_prueflos  = p_prueflos
    188.       i_reset_lot = 'X'
    189.     IMPORTING
    190.       e_qals      = p_qals
    191.     EXCEPTIONS
    192.       no_lot      = 1.
    193.  
    194.   p_subrc = sy-subrc.
    195.   IF p_subrc IS INITIAL.
    196.     p_qals_leiste = p_qals.
    197.   ELSE.
    198.     CLEAR: p_qals,
    199.            p_qals_leiste.
    200.   ENDIF.
    201.  
    202. ENDFORM.                               " READ_QALS
    203.  
    204. *----------------------------------------------------------------------*
    205. *       Form  CHECK_LOT                                                *
    206. *----------------------------------------------------------------------*
    207. *       Pr黤los pr黤en                                                 *
    208. *----------------------------------------------------------------------*
    209. FORM check_lot USING p_qals  LIKE qals
    210.                      p_subrc LIKE sy-subrc.
    211.  
    212.   DATA:
    213.     l_stat     LIKE jstat,
    214.     l_stat_tab LIKE jstat OCCURS 0 WITH HEADER LINE.
    215.  
    216.   p_subrc = 256.
    217.  
    218. */No reference to material document
    219.   IF p_qals-zeile IS INITIAL.
    220.     EXIT.
    221.   ELSE.
    222.     p_subrc = 128.
    223.   ENDIF.
    224.  
    225. */Serialized Material
    226.   IF NOT p_qals-sernp IS INITIAL.
    227.     EXIT.
    228.   ELSE.
    229.     p_subrc = 64.
    230.   ENDIF.
    231.  
    232. */BERF
    233.   CALL FUNCTION 'STATUS_CHECK'
    234.     EXPORTING
    235.       objnr             = p_qals-objnr
    236.       status            = 'I0203'
    237.     EXCEPTIONS
    238.       status_not_active = 2.
    239.  
    240.   IF NOT sy-subrc IS INITIAL.
    241.     EXIT.
    242.   ELSE.
    243.     p_subrc = 32.
    244.   ENDIF.
    245.  
    246. */BTEI & BEND
    247.   CLEAR l_stat. CLEAR l_stat_tab. REFRESH l_stat_tab.
    248.   l_stat-stat = 'I0219'. APPEND l_stat TO l_stat_tab. "BTEI
    249.   l_stat-stat = 'I0220'. APPEND l_stat TO l_stat_tab. "BEND
    250.  
    251.   CALL FUNCTION 'STATUS_OBJECT_CHECK_MULTI'
    252.     EXPORTING
    253.       objnr        = p_qals-objnr
    254.     TABLES
    255.       status_check = l_stat_tab.
    256.  
    257.   IF l_stat_tab[] IS INITIAL.
    258.     EXIT.
    259.   ELSE.
    260.     p_subrc = 16.
    261.   ENDIF.
    262.  
    263.  
    264. */LSTO & LSTV
    265.   CLEAR l_stat. CLEAR l_stat_tab. REFRESH l_stat_tab.
    266.   l_stat-stat = 'I0224'. APPEND l_stat TO l_stat_tab. "LSTO
    267.   l_stat-stat = 'I0232'. APPEND l_stat TO l_stat_tab. "LSTV
    268.  
    269.   CALL FUNCTION 'STATUS_OBJECT_CHECK_MULTI'
    270.     EXPORTING
    271.       objnr        = p_qals-objnr
    272.     TABLES
    273.       status_check = l_stat_tab.
    274.  
    275.   IF NOT l_stat_tab[] IS INITIAL.
    276.     EXIT.
    277.   ELSE.
    278.     p_subrc = 8.
    279.   ENDIF.
    280.  
    281. */ARSP & ARCH & REO1 & REO2 & REO3
    282.   CLEAR l_stat. CLEAR l_stat_tab. REFRESH l_stat_tab.
    283.   l_stat-stat = 'I0225'. APPEND l_stat TO l_stat_tab. "ARSP
    284.   l_stat-stat = 'I0226'. APPEND l_stat TO l_stat_tab. "ARCH
    285.   l_stat-stat = 'I0227'. APPEND l_stat TO l_stat_tab.       "REO3
    286.   l_stat-stat = 'I0228'. APPEND l_stat TO l_stat_tab.       "REO2
    287.   l_stat-stat = 'I0229'. APPEND l_stat TO l_stat_tab.       "REO1
    288.  
    289.   CALL FUNCTION 'STATUS_OBJECT_CHECK_MULTI'
    290.     EXPORTING
    291.       objnr        = p_qals-objnr
    292.     TABLES
    293.       status_check = l_stat_tab.
    294.  
    295.   IF NOT l_stat_tab[] IS INITIAL.
    296.     EXIT.
    297.   ELSE.
    298.     p_subrc = 4.
    299.   ENDIF.
    300.  
    301. */SPER
    302.   CALL FUNCTION 'STATUS_CHECK'
    303.     EXPORTING
    304.       objnr             = p_qals-objnr
    305.       status            = 'I0043'
    306.     EXCEPTIONS
    307.       status_not_active = 2.
    308.  
    309.   IF sy-subrc IS INITIAL.
    310.     EXIT.
    311.   ELSE.
    312.     p_subrc = 2.
    313.   ENDIF.
    314.  
    315. */HUM
    316.   CALL FUNCTION 'STATUS_CHECK'
    317.     EXPORTING
    318.       objnr             = p_qals-objnr
    319.       status            = 'I0443'
    320.     EXCEPTIONS
    321.       status_not_active = 2.
    322.  
    323.   IF sy-subrc IS INITIAL.
    324.     EXIT.
    325.   ELSE.
    326.     p_subrc = 0.
    327.   ENDIF.
    328.  
    329.  
    330. ENDFORM.                               " CHECK_LOT
    331.  
    332. *----------------------------------------------------------------------*
    333. *       Form  READ_QAMB                                                *
    334. *----------------------------------------------------------------------*
    335. *       QAMBs lesen                                                    *
    336. *----------------------------------------------------------------------*
    337. FORM read_qamb USING p_qals     LIKE qals
    338.                      p_qamb_tab TYPE qambtab
    339.                      p_subrc    LIKE sy-subrc.
    340.  
    341.   CLEAR: p_subrc.
    342.  
    343.   SELECT * FROM qamb INTO TABLE p_qamb_tab
    344.     WHERE prueflos =  p_qals-prueflos
    345.       AND typ   = '3'.
    346.  
    347.   p_subrc = sy-subrc.
    348.  
    349. ENDFORM.                               " READ_QAMB
    350.  
    351. *----------------------------------------------------------------------*
    352. *       Form  READ_MKPF                                                *
    353. *----------------------------------------------------------------------*
    354. *       Read material document header                                  *
    355. *----------------------------------------------------------------------*
    356. FORM read_mkpf USING p_qamb_tab TYPE qambtab
    357.                      p_mkpf_tab TYPE t_mkpf_tab
    358.                      p_subrc    LIKE sy-subrc.
    359.  
    360.   DATA:
    361.     BEGIN OF l_mkpf_key_tab OCCURS 0,
    362.       mblnr LIKE mkpf-mblnr,
    363.       mjahr LIKE mkpf-mjahr,
    364.     END   OF l_mkpf_key_tab.
    365.   DATA:
    366.     l_qamb  LIKE qamb,
    367.     l_mkpf  LIKE mkpf,
    368.     l_trtyp LIKE t158-trtyp VALUE 'A',
    369.     l_vgart LIKE t158-vgart VALUE 'WQ',
    370.     l_xexit LIKE qm00-qkz.
    371.  
    372.   p_subrc = 4.
    373.  
    374.   LOOP AT p_qamb_tab INTO l_qamb.
    375.     l_mkpf_key_tab-mblnr = l_qamb-mblnr.
    376.     l_mkpf_key_tab-mjahr = l_qamb-mjahr.
    377.     COLLECT l_mkpf_key_tab.
    378.   ENDLOOP.
    379.  
    380.   LOOP AT l_mkpf_key_tab.
    381.     CALL FUNCTION 'ENQUEUE_EMMKPF'
    382.       EXPORTING
    383.         mblnr          = l_mkpf_key_tab-mblnr
    384.         mjahr          = l_mkpf_key_tab-mjahr
    385.       EXCEPTIONS
    386.         foreign_lock   = 1
    387.         system_failure = 2
    388.         OTHERS         = 3.
    389.     IF NOT sy-subrc IS INITIAL.
    390.       l_xexit = 'X'.
    391.       EXIT.
    392.     ENDIF.
    393.  
    394.     CLEAR: l_mkpf.
    395.     CALL FUNCTION 'MB_READ_MATERIAL_HEADER'
    396.       EXPORTING
    397.         mblnr         = l_mkpf_key_tab-mblnr
    398.         mjahr         = l_mkpf_key_tab-mjahr
    399.         trtyp         = l_trtyp
    400.         vgart         = l_vgart
    401.       IMPORTING
    402.         kopf          = l_mkpf
    403.       EXCEPTIONS
    404.         error_message = 1.
    405.  
    406.     IF NOT sy-subrc IS INITIAL.
    407.       l_xexit = 'X'.
    408.       EXIT.
    409.     ELSE.
    410.       APPEND l_mkpf TO p_mkpf_tab.
    411.     ENDIF.
    412.  
    413.   ENDLOOP.
    414.  
    415.   IF NOT l_xexit IS INITIAL.
    416.     EXIT.
    417.   ELSE.
    418.     p_subrc = 0.
    419.   ENDIF.
    420.  
    421. ENDFORM.                               " READ_MKPF
    422.  
    423. *----------------------------------------------------------------------*
    424. *       Form  READ_MSEG                                                *
    425. *----------------------------------------------------------------------*
    426. *       MSEGs lesen                                                    *
    427. *----------------------------------------------------------------------*
    428. FORM read_mseg USING p_mkpf_tab TYPE t_mkpf_tab
    429.                      p_mseg_tab TYPE t_mseg_tab
    430.                      p_subrc    LIKE sy-subrc.
    431.  
    432.   DATA:
    433.     l_mkpf     LIKE mkpf,
    434.     l_mseg_tab LIKE mseg OCCURS 0 WITH HEADER LINE,
    435.     l_trtyp    LIKE t158-trtyp VALUE 'A',
    436.     l_xexit    LIKE qm00-qkz.
    437.  
    438.   p_subrc = 4.
    439.  
    440.   LOOP AT p_mkpf_tab INTO l_mkpf.
    441.  
    442.     CLEAR: l_mseg_tab. REFRESH: l_mseg_tab.
    443.     CALL FUNCTION 'MB_READ_MATERIAL_POSITION'
    444.       EXPORTING
    445.         mblnr         = l_mkpf-mblnr
    446.         mjahr         = l_mkpf-mjahr
    447.         trtyp         = l_trtyp
    448. */            ZEILB  = P_ZEILE
    449. */            ZEILE  = P_ZEILE
    450.       TABLES
    451.         seqtab        = l_mseg_tab
    452.       EXCEPTIONS
    453.         error_message = 1.
    454.  
    455.     IF NOT sy-subrc IS INITIAL.
    456.       l_xexit = 'X'.
    457.       EXIT.
    458.     ELSE.
    459.       APPEND LINES OF l_mseg_tab TO p_mseg_tab.
    460.     ENDIF.
    461.  
    462.   ENDLOOP.
    463.  
    464.   IF NOT l_xexit IS INITIAL.
    465.     EXIT.
    466.   ELSE.
    467. */  XAuto-Zeilen und Chargenzustands鋘derung werden gel鰏cht
    468.     DELETE p_mseg_tab WHERE xauto NE space
    469.                          OR bwart EQ '341'
    470.                          OR bwart EQ '342'.
    471.  
    472.     p_subrc = 0.
    473.   ENDIF.
    474.  
    475. ENDFORM.                               " READ_MSEG
    476.  
    477. *----------------------------------------------------------------------*
    478. *       Form  CREATE_GOODS_MOVEMENT                                    *
    479. *----------------------------------------------------------------------*
    480. *       Warenbewegung anlegen                                          *
    481. *----------------------------------------------------------------------*
    482. FORM create_goods_movement USING p_qals     LIKE qals
    483.                                  p_mseg_tab TYPE t_mseg_tab
    484.                                  p_subrc    LIKE sy-subrc.
    485.  
    486.   DATA:
    487.     l_lmengezub LIKE qals-lmengezub,
    488.     l_lmengegeb LIKE qals-lmengezub,
    489.     l_mbqss     LIKE mbqss,
    490.     l_imkpf     LIKE imkpf,
    491.     l_imseg     LIKE imseg,
    492.     l_imseg_tab LIKE imseg OCCURS 1,
    493.     l_emkpf     LIKE emkpf,
    494.     l_emseg     LIKE emseg,
    495.     l_emseg_tab LIKE emseg OCCURS 1,
    496.     l_mseg      LIKE mseg,
    497.     l_mseg_tab  LIKE mseg  OCCURS 1,
    498.     l_tcode     LIKE sy-tcode VALUE 'QA11',
    499.     l_tabix     LIKE sy-tabix VALUE 1,
    500.     l_xstbw     LIKE t156-xstbw.
    501.  
    502.   CLEAR: p_subrc.
    503.  
    504. */QAMB initialisieren
    505.   CALL FUNCTION 'QAMB_REFRESH_DATA'.
    506.  
    507. */Kopf f黮len
    508.   l_imkpf-bldat = sy-datlo.
    509.   l_imkpf-budat = sy-datlo.
    510.   l_imkpf-bktxt = 'Cancellation of QM UD postings'.
    511.  
    512. */Urspr黱gliche zu buchende Menge merken + inkrementieren
    513.   l_lmengezub = p_qals-lmengezub.
    514.   l_lmengegeb =   p_qals-lmenge01
    515.                 + p_qals-lmenge02
    516.                 + p_qals-lmenge03
    517.                 + p_qals-lmenge04
    518.                 + p_qals-lmenge05
    519.                 + p_qals-lmenge06
    520.                 + p_qals-lmenge07
    521.                 + p_qals-lmenge08
    522.                 + p_qals-lmenge09.
    523.  
    524.  
    525. */Zeilen aufbauen
    526.   l_mseg_tab[] = p_mseg_tab[].
    527.  
    528.   LOOP AT l_mseg_tab INTO l_mseg.
    529.     MOVE-CORRESPONDING l_mseg  TO l_mbqss.
    530.     MOVE-CORRESPONDING l_mbqss TO l_imseg.
    531. */  Referenzbeleg 黚ergeben, falls Bestellnummer gef黮lt
    532.     IF NOT l_mseg-ebeln IS INITIAL.
    533.       MOVE: l_mseg-lfbnr TO l_imseg-lfbnr,
    534.             l_mseg-lfbja TO l_imseg-lfbja,
    535.             l_mseg-lfpos TO l_imseg-lfpos.
    536.     ENDIF.
    537.     MOVE l_mseg-kdauf          TO l_imseg-kdauf.
    538.     MOVE l_mseg-kdpos          TO l_imseg-kdpos.
    539.     MOVE l_mseg-ps_psp_pnr     TO l_imseg-ps_psp_pnr.
    540.  
    541. */  Umlagerungsfelder setzen
    542.     MOVE:
    543.         l_mseg-ummat  TO l_imseg-ummat,
    544.         l_mseg-umwrk  TO l_imseg-umwrk,
    545.         l_mseg-umlgo  TO l_imseg-umlgo,
    546.         l_mseg-umcha  TO l_imseg-umcha.
    547.  
    548. */  Storno-Beleg setzen
    549.     MOVE: l_mseg-mjahr  TO l_imseg-sjahr,
    550.           l_mseg-mblnr  TO l_imseg-smbln,
    551.           l_mseg-zeile  TO l_imseg-smblp.
    552.  
    553. */  Falsch gef黮lte Felder initialisieren
    554.     CLEAR: l_imseg-mblnr,
    555.            l_imseg-menge,
    556.            l_imseg-meins.
    557.  
    558. */  Bewegungsart lesen
    559.     SELECT SINGLE xstbw FROM t156 INTO l_xstbw
    560.       WHERE bwart = l_imseg-bwart.
    561.     IF NOT sy-subrc IS INITIAL.
    562.       p_subrc = 4.
    563.       EXIT.
    564.     ENDIF.
    565.  
    566. */  Werk/Lagerort f黮len
    567.     IF p_qals-stat11 IS INITIAL.
    568.  
    569.       IF l_xstbw IS INITIAL.
    570.         MOVE p_qals-lagortvorg TO l_imseg-lgort.
    571.       ELSE.
    572.         MOVE p_qals-lagortvorg TO l_imseg-umlgo.
    573.       ENDIF.
    574.     ENDIF.
    575.     IF l_xstbw IS INITIAL.
    576.       MOVE p_qals-werkvorg TO l_imseg-werks.
    577.     ELSE.
    578.       MOVE p_qals-werkvorg TO l_imseg-umwrk.
    579.     ENDIF.
    580.  
    581. */  Zus鋞zliche Felder
    582.     MOVE p_qals-mengeneinh TO l_imseg-erfme.
    583.     "MOVE P_GRUND           TO L_IMSEG-GRUND.
    584.     "MOVE P_ELIKZ           TO L_IMSEG-ELIKZ.
    585. */  Kennzeichen Storno-Buchung setzen
    586.     MOVE 'X'               TO l_imseg-xstob.
    587.     MOVE p_qals-prueflos   TO l_imseg-qplos.
    588.  
    589.     APPEND l_imseg TO l_imseg_tab.
    590.     IF p_qals-stat11 IS INITIAL.
    591.       ADD      l_imseg-erfmg TO   l_lmengezub.
    592.       SUBTRACT l_imseg-erfmg FROM l_lmengegeb.
    593.     ELSE.
    594.       IF     l_imseg-kzbew EQ space
    595.          AND l_imseg-werks NE space
    596.          AND l_imseg-lgort NE space
    597.          AND l_imseg-umwrk NE space
    598.          AND l_imseg-umlgo NE space
    599.          AND l_imseg-werks EQ l_imseg-umwrk
    600.          AND l_imseg-umlgo EQ l_imseg-umlgo.
    601. */      Dummy Buchung bei WE-Sperrbestand & Stichprobe
    602.       ELSE.
    603.         ADD      l_imseg-erfmg TO   l_lmengezub.
    604.         SUBTRACT l_imseg-erfmg FROM l_lmengegeb.
    605.       ENDIF.
    606.     ENDIF.
    607.   ENDLOOP.
    608.  
    609.   IF NOT p_qals-stat11 IS INITIAL.
    610. */  Bei WE-Sperrbestand und Stichprobenbuchung Zeilen tauschen
    611.     DO.
    612.       READ TABLE l_imseg_tab INDEX sy-index INTO l_imseg.
    613.       IF     sy-subrc      IS INITIAL
    614.          AND l_imseg-kzbew EQ space
    615.          AND l_imseg-werks NE space
    616.          AND l_imseg-lgort NE space
    617.          AND l_imseg-umwrk NE space
    618.          AND l_imseg-umlgo NE space
    619.          AND l_imseg-werks EQ l_imseg-umwrk
    620.          AND l_imseg-umlgo EQ l_imseg-umlgo.
    621.  
    622.         IF sy-tabix NE l_tabix.
    623.           DELETE l_imseg_tab INDEX sy-tabix.
    624.           INSERT l_imseg     INTO  l_imseg_tab INDEX l_tabix.
    625.           l_tabix = l_tabix + 1.
    626.         ELSE.
    627.           l_tabix = l_tabix + 1.
    628.           CONTINUE.
    629.         ENDIF.
    630.       ELSEIF sy-subrc IS INITIAL.
    631.         CONTINUE.
    632.       ELSE.
    633.         EXIT.                          "from do
    634.       ENDIF.
    635.     ENDDO.
    636.   ENDIF.
    637.  
    638. */QM deaktivieren
    639.   CALL FUNCTION 'QAAT_QM_ACTIVE_INACTIVE'
    640.     EXPORTING
    641.       aktiv = space.
    642. */Buchen
    643.   CALL FUNCTION 'MB_CREATE_GOODS_MOVEMENT'
    644.     EXPORTING
    645.       imkpf = l_imkpf
    646.       xallp = 'X'
    647.       xallr = 'X'
    648.       ctcod = l_tcode
    649.       xqmcl = ' '
    650.     IMPORTING
    651.       emkpf = l_emkpf
    652.     TABLES
    653.       imseg = l_imseg_tab
    654.       emseg = l_emseg_tab.
    655. */QM wieder aktivieren
    656.   CALL FUNCTION 'QAAT_QM_ACTIVE_INACTIVE'
    657.     EXPORTING
    658.       aktiv = 'X'.
    659.  
    660. */Buchung auswerten
    661.   IF l_emkpf-subrc GT 1.
    662.     IF l_emkpf-msgid NE space.
    663. */    Fehler auf Kopfebene
    664.       MESSAGE ID l_emkpf-msgid TYPE 'S'
    665.               NUMBER l_emkpf-msgno
    666.               WITH l_emkpf-msgv1 l_emkpf-msgv2
    667.                    l_emkpf-msgv3 l_emkpf-msgv4.
    668.       SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    669.     ELSE.
    670. */    Fehler auf Zeilenebene (Ausgabe des ersten Fehlers)
    671.       LOOP AT l_emseg_tab INTO l_emseg.
    672.         IF l_emseg-msgid NE space.
    673.           MESSAGE ID l_emseg-msgid TYPE 'S'
    674.                 NUMBER l_emseg-msgno
    675.                 WITH l_emseg-msgv1 l_emseg-msgv2
    676.                      l_emseg-msgv3 l_emseg-msgv4.
    677.           SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    678.         ENDIF.
    679.       ENDLOOP.
    680.     ENDIF.
    681.   ENDIF.
    682.  
    683.   LOOP AT l_emseg_tab INTO l_emseg.
    684.     CALL FUNCTION 'QAMB_COLLECT_RECORD'
    685.       EXPORTING
    686.         lotnumber   = p_qals-prueflos
    687.         docyear     = l_emkpf-mjahr
    688.         docnumber   = l_emkpf-mblnr
    689.         docposition = l_emseg-mblpo
    690.         type        = '7'.
    691.   ENDLOOP.
    692.  
    693. */Sonderkorrektur f黵 Frei-An-Frei & WE-Sperr-An-We-Sperr
    694.   IF NOT p_qals-stat11 IS INITIAL.
    695.     IF p_qals-lmenge04 EQ l_lmengegeb.
    696.       ADD      p_qals-lmenge04 TO   l_lmengezub.
    697.       SUBTRACT p_qals-lmenge04 FROM l_lmengegeb.
    698.     ENDIF.
    699.   ELSEIF p_qals-insmk IS INITIAL.
    700.     IF         p_qals-lmenge01 GE l_lmengegeb
    701.        AND NOT p_qals-lmenge01 IS INITIAL.
    702.       ADD      l_lmengegeb     TO   l_lmengezub.
    703.       SUBTRACT l_lmengegeb     FROM l_lmengegeb.
    704.     ENDIF.
    705.   ENDIF.
    706.  
    707.   CLEAR: p_qals-stat34,
    708.          p_qals-matnrneu,
    709.          p_qals-chargneu,
    710.          p_qals-lmenge01,
    711.          p_qals-lmenge02,
    712.          p_qals-lmenge03,
    713.          p_qals-lmenge04,
    714.          p_qals-lmenge05,
    715.          p_qals-lmenge06,
    716.          p_qals-lmenge07,
    717.          p_qals-lmenge08,
    718.          p_qals-lmenge09.
    719.  
    720.   p_qals-lmengezub = l_lmengezub.
    721.   IF NOT l_lmengegeb IS INITIAL.
    722.     p_subrc = 4.
    723.   ENDIF.
    724.  
    725. ENDFORM.                               " CREATE_GOODS_MOVEMENT
    726.  
    727. *----------------------------------------------------------------------*
    728. *       Form  POST_GOODS_MOVEMENT                                      *
    729. *----------------------------------------------------------------------*
    730. *       Warenbewegung buchen                                           *
    731. *----------------------------------------------------------------------*
    732. FORM post_goods_movement.
    733.  
    734.   CALL FUNCTION 'MB_POST_GOODS_MOVEMENT'.
    735.  
    736. ENDFORM.                               " POST_GOODS_MOVEMENT
    737.  
    738. *----------------------------------------------------------------------*
    739. *       Form  POST_DATA                                                *
    740. *----------------------------------------------------------------------*
    741. *       QM-Daten verbuchen                                             *
    742. *----------------------------------------------------------------------*
    743. FORM post_data USING p_qals        LIKE qals
    744.                      p_qals_leiste LIKE qals
    745.                      p_qamb_tab    TYPE qambtab
    746.                      p_qamb_vb_tab TYPE qambtab
    747.                      p_subrc       LIKE sy-subrc.
    748.  
    749.   DATA:
    750.     l_stat     LIKE jstat,
    751.     l_stat_tab LIKE jstat OCCURS 0,
    752.     l_qamb     LIKE qamb,
    753.     l_updkz    LIKE qalsvb-upsl VALUE 'U'.
    754.  
    755. */QAMBs umsetzen (7 = VE-Buchung storniert)
    756.   LOOP AT p_qamb_tab INTO l_qamb.
    757.     l_qamb-typ = '7'.
    758.     APPEND l_qamb TO p_qamb_vb_tab.
    759.   ENDLOOP.
    760.  
    761. */BERF & BTEI zur點knehmen
    762.   CLEAR l_stat. CLEAR l_stat_tab.
    763.   l_stat-inact = 'X'.
    764.   l_stat-stat = 'I0219'. APPEND l_stat TO l_stat_tab. "BTEI
    765.   l_stat-stat = 'I0220'. APPEND l_stat TO l_stat_tab. "BEND
    766.  
    767.   CALL FUNCTION 'STATUS_CHANGE_INTERN'
    768.     EXPORTING
    769.       objnr         = p_qals-objnr
    770.     TABLES
    771.       status        = l_stat_tab
    772.     EXCEPTIONS
    773.       error_message = 1.
    774.  
    775.   IF sy-subrc <> 0.
    776.     MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
    777.             WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    778.     SUBMIT (sy-repid) VIA SELECTION-SCREEN.
    779.   ENDIF.
    780.  
    781. */Pr黤los aktualisieren
    782.   CALL FUNCTION 'QPL1_UPDATE_MEMORY'
    783.     EXPORTING
    784.       i_qals  = p_qals
    785.       i_updkz = l_updkz.
    786.  
    787.   CALL FUNCTION 'QPL1_INSPECTION_LOTS_POSTING'
    788.     EXPORTING
    789.       i_mode = '1'.
    790.  
    791.   CALL FUNCTION 'STATUS_UPDATE_ON_COMMIT'.
    792.  
    793. */QAMB initialisieren
    794.   CALL FUNCTION 'QAMB_REFRESH_DATA'.
    795.  
    796.   PERFORM update_qamb ON COMMIT.
    797.  
    798.   p_subrc = 0.
    799.  
    800. ENDFORM.                               " POST_DATA
    801.  
    802. *----------------------------------------------------------------------*
    803. *       Form  UPDATE_QAMB                                              *
    804. *----------------------------------------------------------------------*
    805. *       Update auf QAMB                                                *
    806. *----------------------------------------------------------------------*
    807. FORM update_qamb.
    808.  
    809.   CALL FUNCTION 'QEVA_QAMB_CANCEL' IN UPDATE TASK
    810.     EXPORTING
    811.       t_qamb_tab = g_qamb_vb_tab.
    812.  
    813. ENDFORM.                               " UPDATE_QAMB
    814.  
    815. *----------------------------------------------------------------------*
    816. *       Form  CHECK_MSEG                                               *
    817. *----------------------------------------------------------------------*
    818. *       MSEGs pr黤en                                                   *
    819. *----------------------------------------------------------------------*
    820. FORM check_mseg USING p_mseg_tab TYPE t_mseg_tab
    821.                       p_qamb_tab TYPE qambtab
    822.                       p_subrc    LIKE sy-subrc.
    823.  
    824.   DATA:
    825.     l_mseg_stor_tab LIKE mseg OCCURS 0 WITH HEADER LINE.
    826.  
    827.   CLEAR: p_subrc.
    828.  
    829. */Zeilen bereits storniert?
    830.   SELECT mblnr mjahr zeile smbln sjahr smblp
    831.     FROM mseg INTO CORRESPONDING FIELDS OF TABLE l_mseg_stor_tab
    832.     FOR ALL ENTRIES IN p_mseg_tab
    833.     WHERE smbln EQ p_mseg_tab-mblnr
    834.       AND sjahr EQ p_mseg_tab-mjahr
    835.       AND smblp EQ p_mseg_tab-zeile.
    836.  
    837.   IF sy-subrc IS INITIAL.
    838.     LOOP AT l_mseg_stor_tab.
    839.       DELETE p_mseg_tab WHERE     mblnr = l_mseg_stor_tab-smbln
    840.                               AND mjahr = l_mseg_stor_tab-sjahr
    841.                               AND zeile = l_mseg_stor_tab-smblp.
    842.       DELETE p_qamb_tab WHERE     mblnr = l_mseg_stor_tab-smbln
    843.                               AND mjahr = l_mseg_stor_tab-sjahr
    844.                               AND zeile = l_mseg_stor_tab-smblp.
    845.     ENDLOOP.
    846.     IF p_mseg_tab[] IS INITIAL.
    847.       p_subrc = 4.
    848.       EXIT.
    849.     ENDIF.
    850.   ENDIF.
    851.  
    852. ENDFORM.                               " CHECK_MSEG
    853. *----------------------------------------------------------------------*
    854. *       Form  CHECK_MKPF                                               *
    855. *----------------------------------------------------------------------*
    856. *       Materialbelege pr黤en (Wurde durch VE-Buchung Pr黤llos erzeugt?*
    857. *----------------------------------------------------------------------*
    858. FORM check_mkpf USING p_mkpf_tab TYPE t_mkpf_tab
    859.                       p_subrc    LIKE sy-subrc.
    860.  
    861.   DATA:
    862.     l_mkpf_tab TYPE t_mkpf_tab.
    863.  
    864.   CLEAR: p_subrc.
    865.  
    866.   SELECT mblnr FROM qamb INTO CORRESPONDING FIELDS OF TABLE l_mkpf_tab
    867.     FOR ALL ENTRIES IN p_mkpf_tab
    868.     WHERE mblnr EQ p_mkpf_tab-mblnr
    869.       AND mjahr EQ p_mkpf_tab-mjahr
    870.       AND typ   = '1'.
    871.  
    872.   IF sy-subrc IS INITIAL.
    873.     p_subrc = 4.
    874.   ENDIF.
    875.  
    876. ENDFORM.                               " CHECK_MKPF

  • 相关阅读:
    数据结构与算法------数组
    linux 编译安装 opencv 和指定 opencv_contrib 库
    JVM虚拟机-虚拟机执行子系统-第6章 字节码指令
    数据分析案例-基于sklearn随机森林算法探究影响预期寿命的因素
    初识node.js
    JavaScript奇淫技巧：把JS编译成exe
    【技术积累】算法中的动态规划【一】
    gd32F470串口重定义
    【.NET8】访问私有成员新姿势UnsafeAccessor（下）
    DDoS渗透与攻防实战 （一） ： 初识DDoS
  • 原文地址：https://blog.csdn.net/csui2008/article/details/125617123