ABAP 选择屏幕多页签

SELECTION-SCREEN BEGIN OF SCREEN 9001 AS SUBSCREEN .
SELECTION-SCREEN BEGIN OF BLOCK BK1 WITH FRAME TITLE TEXT-001.
PARAMETERS: P_VKORG1 TYPE VBAK-VKORG MODIF ID MD1.
SELECT-OPTIONS: S_VSTEL1 FOR LIKP-VSTEL,
                S_KUNNR1 FOR VBAK-KUNNR.
SELECTION-SCREEN END OF BLOCK BK1.
 
SELECTION-SCREEN BEGIN OF BLOCK BK2 WITH FRAME TITLE TEXT-002.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(31) TEXT-P01 FOR FIELD P_FKDAT1.
PARAMETERS: P_FKDAT1 LIKE VBCO7-FKDAT.
SELECTION-SCREEN COMMENT 52(5) TEXT-P02 FOR FIELD P_FKDAB1.
PARAMETERS: P_FKDAB1 LIKE VBCO7-FKDAT_BIS DEFAULT SY-DATLO.
SELECTION-SCREEN END OF LINE.
SELECT-OPTIONS: S_FKART1 FOR VBRK-FKART NO-DISPLAY,
                S_VBELN1 FOR VBAK-VBELN.
SELECTION-SCREEN END OF BLOCK BK2.
 
SELECTION-SCREEN BEGIN OF BLOCK BK3 WITH FRAME TITLE TEXT-003.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_R1 AS CHECKBOX DEFAULT 'X'.
SELECTION-SCREEN COMMENT (20) TEXT-101 FOR FIELD P_R1.
PARAMETERS: P_R2 AS CHECKBOX DEFAULT 'X'.
SELECTION-SCREEN COMMENT (20) TEXT-102 FOR FIELD P_R2.
PARAMETERS: P_R3 AS CHECKBOX.
SELECTION-SCREEN COMMENT (20) TEXT-103 FOR FIELD P_R3.
PARAMETERS: P_R4 AS CHECKBOX.
SELECTION-SCREEN COMMENT (20) TEXT-104 FOR FIELD P_R4.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK BK3.
 
SELECTION-SCREEN BEGIN OF BLOCK BK7 WITH FRAME TITLE TEXT-007.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_R7 RADIOBUTTON GROUP RGP1 DEFAULT 'X'.
SELECTION-SCREEN COMMENT (20) TEXT-107 FOR FIELD P_R7.
PARAMETERS: P_R8 RADIOBUTTON GROUP RGP1.
SELECTION-SCREEN COMMENT (20) TEXT-108 FOR FIELD P_R8.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK BK7.
 
SELECTION-SCREEN END OF SCREEN 9001.
 
SELECTION-SCREEN BEGIN OF SCREEN 9002 AS SUBSCREEN.
 
SELECTION-SCREEN BEGIN OF BLOCK BK4 WITH FRAME TITLE TEXT-004.
SELECT-OPTIONS: S_VBELN2 FOR VBRK-VBELN,
                S_FKART2 FOR VBRK-FKART NO-DISPLAY,
                S_FKDAT2 FOR VBRK-FKDAT.
SELECTION-SCREEN END OF BLOCK BK4.
 
SELECTION-SCREEN BEGIN OF BLOCK BK5 WITH FRAME TITLE TEXT-005.
SELECT-OPTIONS: S_VKORG2 FOR VBRK-VKORG MODIF ID MD1,
                S_VTWEG2 FOR VBRK-VTWEG,
                S_KUNNR2 FOR VBRK-KUNRG.
SELECTION-SCREEN END OF BLOCK BK5.
 
 
SELECTION-SCREEN BEGIN OF BLOCK BK6 WITH FRAME TITLE TEXT-006.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_R5 AS CHECKBOX DEFAULT 'X'.
SELECTION-SCREEN COMMENT (20) TEXT-105 FOR FIELD P_R5.
PARAMETERS: P_R6 AS CHECKBOX.
SELECTION-SCREEN COMMENT (20) TEXT-106 FOR FIELD P_R6.
SELECTION-SCREEN END OF LINE.
 
SELECTION-SCREEN END OF BLOCK BK6.
 
SELECTION-SCREEN BEGIN OF BLOCK BK8 WITH FRAME TITLE TEXT-008.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_R9 RADIOBUTTON GROUP RGP2 DEFAULT 'X'.
SELECTION-SCREEN COMMENT (20) TEXT-107 FOR FIELD P_R9.
PARAMETERS: P_R10 RADIOBUTTON GROUP RGP2.
SELECTION-SCREEN COMMENT (20) TEXT-108 FOR FIELD P_R10.
PARAMETERS: P_R11 RADIOBUTTON GROUP RGP2.
SELECTION-SCREEN COMMENT (20) TEXT-109 FOR FIELD P_R11.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK BK8.
 
SELECTION-SCREEN END OF SCREEN 9002.
SELECTION-SCREEN:BEGIN OF TABBED BLOCK MYTAB FOR 25 LINES,
                 TAB (20) P_TAB1 USER-COMMAND TAB1,
                 TAB (20) P_TAB2 USER-COMMAND TAB2,
               END OF BLOCK MYTAB.

INITIALIZATION.
  PERFORM FRM_INIT_TAB.
 
AT SELECTION-SCREEN.
  PERFORM FRM_CHANGE_DYNNR.
 
FORM FRM_INIT_TAB .
  DATA: LV_DYNNR TYPE SYST_DYNNR.
  P_TAB1 = '待开票清单'.
  P_TAB2 = '发票清单'.
  MYTAB-PROG = SY-REPID.
 
  GET PARAMETER ID 'ZDYNNR_SD' FIELD LV_DYNNR.
  IF LV_DYNNR IS NOT INITIAL.
    CASE LV_DYNNR.
      WHEN '9001'.
        MYTAB-DYNNR = 9001.
        MYTAB-ACTIVETAB = 'TAB1'.
      WHEN '9002'.
        MYTAB-DYNNR = 9002.
        MYTAB-ACTIVETAB = 'TAB2'.
    ENDCASE.
  ELSE.
    MYTAB-DYNNR = 9001.
    MYTAB-ACTIVETAB = 'TAB1'.
  ENDIF.
ENDFORM.
 
FORM FRM_CHANGE_DYNNR .
  CASE SY-DYNNR.
    WHEN 1000.
      CASE SY-UCOMM.
        WHEN 'TAB1'.
          MYTAB-DYNNR = 9001.
          MYTAB-ACTIVETAB = 'TAB1'.
        WHEN 'TAB2'.
          MYTAB-DYNNR = 9002.
          MYTAB-ACTIVETAB = 'TAB2'.
        WHEN OTHERS.
      ENDCASE.
    WHEN OTHERS.
  ENDCASE.
ENDFORM.

关于返回屏幕上，还是停留在原来页签上，通过SET PARAMETER ID 'ZDYNNR_SD' FIELD MYTAB-DYNNR.