• ABAP 遗传算法求解

            本文无文本解析，结尾处有简单装箱问题的示例，该算法收敛结果较慢，仅供ABAP爱好者参考，实践，实际应用建议使用线性规划。可直接复制后在系统中使用。

    对象自定义逻辑版本-截图

    对象自定义逻辑版本-对象描述
    1. INIT    Instance Method    Public                                       初始化 
    2. ADD_VAR    Instance Method    Public                                       添加变量
    3. GET_RESULT    Instance Method    Public                                       获取最佳结果 
    4. GET_RECORD    Instance Method    Public                                       获取过程记录
    5. CALCU_FITNESS    Instance Method    Protected                                       适应度计算 
    6. ELIMINATE    Instance Method    Protected                                       淘汰个体
    7. GEN_INI_ETHNICGROUPS    Instance Method    Private                                       生成初始化族群 
    8. CALCULAT_RATE    Instance Method    Private                                       计算概率
    9. UNIT_VAR    Instance Method    Private                                       变异
    10. UNIT_CROSS    Instance Method    Private                                       交叉
    11. RANDOW    Instance Method    Private                                       随机数 
    12. CHECK_GEN_VALID    Instance Method    Private                                       检查是否满足条件 
    13. GEN_UNIT    Instance Method    Private                                       生成单个染色体 
    14. ITERATION    Instance Method    Private                                       迭代繁衍群体
    15.  
    16. VARIATION    Instance Attribute    Protected    Type    FTVV_PART_DEFAULT_PROBABILITY    变异率 
    17. CROSS    Instance Attribute    Protected    Type    FTVV_PART_DEFAULT_PROBABILITY    交叉率 
    18. M    Instance Attribute    Protected    Type    INT4    种群大小
    19. T    Instance Attribute    Protected    Type    INT4    最大迭代次数 
    20. GO_GENTIC_CUS    Instance Attribute    Protected    Type Ref To    ZIF_GENTIC_CUS    Genetic CUS
    21. VARS    Instance Attribute    Private    Type    TT_VAR    涉及变量
    22. ALLGROUPS    Instance Attribute    Private    Type    TT_ALLGROUPS    迭代记录
    23. ETHNICGROUPS    Instance Attribute    Private    Type    TT_ETHNICGROUPS    种群
    24. CURR_T    Instance Attribute    Private    Type    INT4    当前迭代代数
    25. RANDOM_UP    Instance Attribute    Private    Type    I    随机数最大尝试次数 
    26. INDEX    Instance Attribute    Private    Type    INT4    个体编号
    对象自定义逻辑版本-类源代码
    1. class ZCL_GENETIC definition
    2.   public
    3.   create public .
    4.  
    5. public section.
    6.  
    7.   types:
    8.     BEGIN OF ty_allgroups,
    9.       t       TYPE i,
    10.       index   TYPE i,
    11.       units   TYPE chip_property_tab,
    12.       fitness TYPE ftvv_part_default_probability,
    13.     END OF ty_allgroups .
    14.   types:
    15.     tt_allgroups TYPE TABLE OF ty_allgroups .
    16.  
    17.   methods INIT
    18.     importing
    19.       !IV_VARIATION type FTVV_PART_DEFAULT_PROBABILITY default '0.05'
    20.       !IV_CROSS type FTVV_PART_DEFAULT_PROBABILITY default '0.8'
    21.       !IV_M type INT4 default 50
    22.       !IV_T type INT4 default 50
    23.       !IV_RANDOM_UP type I default 100
    24.       !IO_GENETIC_CUS type ref to ZIF_GENTIC_CUS .
    25.   methods ADD_VAR
    26.     importing
    27.       !NAME type STRING
    28.       !LOW type I
    29.       !HIGH type I .
    30.   methods GET_RESULT
    31.     returning
    32.       value(RT_UNITS) type CHIP_PROPERTY_TAB .
    33.   methods GET_RECORD
    34.     exporting
    35.       value(ET_REC) type ZCL_GENETIC_BASE=>TT_ALLGROUPS .
    36. protected section.
    37.  
    38.   types:
    39.     BEGIN OF ty_var,
    40.       name TYPE string,
    41.       low  TYPE i,
    42.       high TYPE i,
    43.     END OF ty_var .
    44.   types:
    45.     tt_var TYPE TABLE OF ty_var .
    46.   types:
    47.     BEGIN OF ty_ethnicgroups,
    48.       index   TYPE i,
    49.       units   TYPE chip_property_tab,
    50.       fitness TYPE ftvv_part_default_probability,
    51.     END OF ty_ethnicgroups .
    52.   types:
    53.     tt_ethnicgroups TYPE TABLE OF ty_ethnicgroups .
    54.  
    55.   data VARIATION type FTVV_PART_DEFAULT_PROBABILITY . " 变异概率
    56.   data CROSS type FTVV_PART_DEFAULT_PROBABILITY . " 交叉概率
    57.   data M type INT4 . " 初始种群大小
    58.   data T type INT4 . " 最大迭代次数
    59.   data GO_GENTIC_CUS type ref to ZIF_GENTIC_CUS .
    60.  
    61.   methods CALCU_FITNESS
    62.     importing
    63.       value(UNITS) type CHIP_PROPERTY_TAB
    64.     returning
    65.       value(FITNESS) type FTVV_PART_DEFAULT_PROBABILITY .
    66.   methods ELIMINATE .
    67. private section.
    68.  
    69.   data VARS type TT_VAR ." 染色体
    70.   data ALLGROUPS type TT_ALLGROUPS ." 所有迭代记录
    71.   data ETHNICGROUPS type TT_ETHNICGROUPS ."种群
    72.   data CURR_T type INT4 ." 当前迭代次数
    73.   data RANDOM_UP type I ." 随机数重试最大次数
    74.   data INDEX type INT4 . " 个体ID
    75.  
    76.   methods GEN_INI_ETHNICGROUPS .
    77.   methods CALCULAT_RATE
    78.     returning
    79.       value(RATE) type PAPLI .
    80.   methods UNIT_VAR
    81.     changing
    82.       !UNITS type CHIP_PROPERTY_TAB .
    83.   methods UNIT_CROSS
    84.     importing
    85.       !UNITS_FA type CHIP_PROPERTY_TAB
    86.       !UNITS_MO type CHIP_PROPERTY_TAB
    87.     returning
    88.       value(UNITS) type CHIP_PROPERTY_TAB .
    89.   methods RANDOW
    90.     importing
    91.       !LOW type I
    92.       !HIGH type I
    93.     returning
    94.       value(VALUE) type I .
    95.   methods CHECK_GEN_VALID
    96.     importing
    97.       !UNITS type CHIP_PROPERTY_TAB
    98.     returning
    99.       value(RV_BOOL) type CHAR1 .
    100.   methods GEN_UNIT
    101.     returning
    102.       value(UNITS) type CHIP_PROPERTY_TAB .
    103.   methods ITERATION .
    104. ENDCLASS.
    105.  
    106.  
    107.  
    108. CLASS ZCL_GENETIC IMPLEMENTATION.
    109.  
    110.  
    111. * <SIGNATURE>---------------------------------------------------------------------------------------+
    112. * | Instance Public Method ZCL_GENETIC->ADD_VAR
    113. * +-------------------------------------------------------------------------------------------------+
    114. * | [--->] NAME                           TYPE        STRING
    115. * | [--->] LOW                            TYPE        I
    116. * | [--->] HIGH                           TYPE        I
    117. * +--------------------------------------------------------------------------------------</SIGNATURE>
    118.   METHOD ADD_VAR.
    119.  
    120.     APPEND VALUE #( name = to_upper( name ) low = low high = high ) TO vars.
    121.  
    122.   ENDMETHOD.
    123.  
    124.  
    125. * <SIGNATURE>---------------------------------------------------------------------------------------+
    126. * | Instance Private Method ZCL_GENETIC->CALCULAT_RATE
    127. * +-------------------------------------------------------------------------------------------------+
    128. * | [<-()] RATE                           TYPE        PAPLI
    129. * +--------------------------------------------------------------------------------------</SIGNATURE>
    130.   method CALCULAT_RATE.
    131.  
    132.    rate = randow( low = 1 high = 1000 ) / 1000.
    133.  
    134.   endmethod.
    135.  
    136.  
    137. * <SIGNATURE>---------------------------------------------------------------------------------------+
    138. * | Instance Protected Method ZCL_GENETIC->CALCU_FITNESS
    139. * +-------------------------------------------------------------------------------------------------+
    140. * | [--->] UNITS                          TYPE        CHIP_PROPERTY_TAB
    141. * | [<-()] FITNESS                        TYPE        FTVV_PART_DEFAULT_PROBABILITY
    142. * +--------------------------------------------------------------------------------------</SIGNATURE>
    143.   METHOD CALCU_FITNESS.
    144.  
    145.     go_gentic_cus->calcu_fitness( EXPORTING units = units CHANGING fitness = fitness ).
    146.  
    147.   ENDMETHOD.
    148.  
    149.  
    150. * <SIGNATURE>---------------------------------------------------------------------------------------+
    151. * | Instance Private Method ZCL_GENETIC->CHECK_GEN_VALID
    152. * +-------------------------------------------------------------------------------------------------+
    153. * | [--->] UNITS                          TYPE        CHIP_PROPERTY_TAB
    154. * | [<-()] RV_BOOL                        TYPE        CHAR1
    155. * +--------------------------------------------------------------------------------------</SIGNATURE>
    156.   METHOD check_gen_valid.
    157.  
    158.     rv_bool = abap_true.
    159.     go_gentic_cus->check_gen_valid( EXPORTING units = units CHANGING cv_bool = rv_bool ).
    160.  
    161.   ENDMETHOD.
    162.  
    163.  
    164. * <SIGNATURE>---------------------------------------------------------------------------------------+
    165. * | Instance Protected Method ZCL_GENETIC->ELIMINATE
    166. * +-------------------------------------------------------------------------------------------------+
    167. * +--------------------------------------------------------------------------------------</SIGNATURE>
    168.   METHOD ELIMINATE.
    169.  
    170.     DATA: lv_count TYPE i,
    171.           lv_o     TYPE p LENGTH 15,
    172.           lv_rate  TYPE ftvv_part_default_probability.
    173.  
    174.     DATA: lt_ethnicgroups LIKE ethnicgroups,
    175.           ls_ethnicgroups LIKE LINE OF ethnicgroups.
    176.  
    177.     DO random_up TIMES.
    178.  
    179.       lt_ethnicgroups = ethnicgroups.
    180.  
    181.       DESCRIBE TABLE lt_ethnicgroups LINES lv_count.
    182.  
    183.       IF ( lv_count - m ) / m <= 1 / 10.
    184.         EXIT.
    185.       ENDIF.
    186.  
    187.       lv_o = lv_count * lv_count + lv_count.
    188.       SORT lt_ethnicgroups BY fitness DESCENDING .
    189.  
    190.       LOOP AT lt_ethnicgroups INTO ls_ethnicgroups.
    191.         lv_rate = sy-tabix * sy-tabix / lv_o.
    192.         IF lv_rate < ( 1 / 200 ).
    193.           lv_rate = ( 1 / 200 ).
    194.         ENDIF.
    195.         IF calculat_rate( ) <= lv_rate.
    196.           DELETE ethnicgroups WHERE index = ls_ethnicgroups-index.
    197.         ENDIF.
    198.       ENDLOOP.
    199.  
    200.     ENDDO.
    201.  
    202.   ENDMETHOD.
    203.  
    204.  
    205. * <SIGNATURE>---------------------------------------------------------------------------------------+
    206. * | Instance Private Method ZCL_GENETIC->GEN_INI_ETHNICGROUPS
    207. * +-------------------------------------------------------------------------------------------------+
    208. * +--------------------------------------------------------------------------------------</SIGNATURE>
    209.   METHOD GEN_INI_ETHNICGROUPS.
    210.  
    211.     DATA: ls_ethnicgroup LIKE LINE OF ethnicgroups.
    212.  
    213.     DO m * 2 TIMES.
    214.       ls_ethnicgroup-units = gen_unit( ).
    215.       IF ls_ethnicgroup-units IS NOT INITIAL.
    216.         ls_ethnicgroup-index = index.
    217.         index = index + 1.
    218.         APPEND ls_ethnicgroup TO ethnicgroups.
    219.       ENDIF.
    220.  
    221.       IF lines( ethnicgroups ) >= m.
    222.         EXIT.
    223.       ENDIF.
    224.     ENDDO.
    225.  
    226.   ENDMETHOD.
    227.  
    228.  
    229. * <SIGNATURE>---------------------------------------------------------------------------------------+
    230. * | Instance Private Method ZCL_GENETIC->GEN_UNIT
    231. * +-------------------------------------------------------------------------------------------------+
    232. * | [<-()] UNITS                          TYPE        CHIP_PROPERTY_TAB
    233. * +--------------------------------------------------------------------------------------</SIGNATURE>
    234.   METHOD GEN_UNIT.
    235.  
    236.     DATA: ls_unit LIKE LINE OF units,
    237.           lt_unit LIKE  units,
    238.           ls_var  LIKE LINE OF vars.
    239.  
    240.     DO random_up TIMES.
    241.  
    242.       CLEAR lt_unit.
    243.       LOOP AT vars INTO ls_var.
    244.         ls_unit-name  = ls_var-name.
    245.         ls_unit-value = randow( low = ls_var-low high = ls_var-high ).
    246.         APPEND ls_unit TO lt_unit.
    247.       ENDLOOP.
    248.  
    249.       IF check_gen_valid( lt_unit ).
    250.         EXIT.
    251.       ENDIF.
    252.  
    253.       CLEAR lt_unit.
    254.     ENDDO.
    255.  
    256.     units = lt_unit.
    257.  
    258.   ENDMETHOD.
    259.  
    260.  
    261. * <SIGNATURE>---------------------------------------------------------------------------------------+
    262. * | Instance Public Method ZCL_GENETIC->GET_RECORD
    263. * +-------------------------------------------------------------------------------------------------+
    264. * | [<---] ET_REC                         TYPE        ZCL_GENETIC_BASE=>TT_ALLGROUPS
    265. * +--------------------------------------------------------------------------------------</SIGNATURE>
    266.   method GET_RECORD.
    267.  
    268.     et_rec = allgroups.
    269.  
    270.   endmethod.
    271.  
    272.  
    273. * <SIGNATURE>---------------------------------------------------------------------------------------+
    274. * | Instance Public Method ZCL_GENETIC->GET_RESULT
    275. * +-------------------------------------------------------------------------------------------------+
    276. * | [<-()] RT_UNITS                       TYPE        CHIP_PROPERTY_TAB
    277. * +--------------------------------------------------------------------------------------</SIGNATURE>
    278.   METHOD GET_RESULT.
    279.  
    280.     DATA: lt_ethnicgroups LIKE ethnicgroups,
    281.           lv_index        TYPE i.
    282.  
    283.     gen_ini_ethnicgroups( ).
    284.  
    285.     DO t TIMES.
    286.  
    287.       iteration( ).
    288.       eliminate( ).
    289.  
    290.       " 判定是否收敛
    291.       lt_ethnicgroups = ethnicgroups.
    292.       SORT lt_ethnicgroups BY fitness DESCENDING.
    293.       lv_index = lines( lt_ethnicgroups ) / 2.
    294.       IF lv_index >= 1 AND lt_ethnicgroups[ 1 ]-fitness = lt_ethnicgroups[ lv_index ]-fitness.
    295.         EXIT.
    296.       ENDIF.
    298.       IF curr_t > t.
    299.         EXIT.
    300.       ENDIF.
    301.     ENDDO.
    303.     IF ethnicgroups IS NOT INITIAL.
    304.       SORT ethnicgroups BY fitness DESCENDING.
    305.       rt_units = ethnicgroups[ 1 ]-units.
    306.     ENDIF.
    308.   ENDMETHOD.
    311. * ---------------------------------------------------------------------------------------+
    312. * | Instance Public Method ZCL_GENETIC->INIT
    313. * +-------------------------------------------------------------------------------------------------+
    314. * | [--->] IV_VARIATION                   TYPE        FTVV_PART_DEFAULT_PROBABILITY (default ='0.05')
    315. * | [--->] IV_CROSS                       TYPE        FTVV_PART_DEFAULT_PROBABILITY (default ='0.8')
    316. * | [--->] IV_M                           TYPE        INT4 (default =50)
    317. * | [--->] IV_T                           TYPE        INT4 (default =50)
    318. * | [--->] IV_RANDOM_UP                   TYPE        I (default =100)
    319. * | [--->] IO_GENETIC_CUS                 TYPE REF TO ZIF_GENTIC_CUS
    320. * +--------------------------------------------------------------------------------------
    321.   METHOD INIT.
    322. *----------------------------------------------------------------------*
    323. * variation: 变异率 0.01-0.1之间，变异率高可能导致收敛过快
    324. * cross: 交叉率 0.6-0.9之间，交叉率越高范围越广
    325. * m: 种群大小，20-200之间
    326. * t: 最大迭代次数
    327. * random_up: 随机时的重试上限
    328. *----------------------------------------------------------------------*
    329.     variation = iv_variation .
    330.     cross     = iv_cross     .
    331.     m         = iv_m         .
    332.     t         = iv_t         .
    333.     random_up = iv_random_up .
    335.     go_gentic_cus = io_genetic_cus.
    337.   ENDMETHOD.
    340. * ---------------------------------------------------------------------------------------+
    341. * | Instance Private Method ZCL_GENETIC->ITERATION
    342. * +-------------------------------------------------------------------------------------------------+
    343. * +--------------------------------------------------------------------------------------
    344.   METHOD ITERATION.
    346.     DATA: lv_fitnessall TYPE p LENGTH 15 DECIMALS 5,
    347.           lv_rate       TYPE umls1.
    349.     DATA: ls_ethnicgroups LIKE LINE OF ethnicgroups,
    350.           lt_enthicgroups LIKE ethnicgroups,
    351.           ls_allgroups    LIKE LINE OF allgroups,
    352.           lt_allgroups    LIKE allgroups,
    353.           lt_units_ch     TYPE chip_property_tab,
    354.           lt_units_fa     TYPE chip_property_tab,
    355.           lt_units_mo     TYPE chip_property_tab.
    357.     LOOP AT ethnicgroups INTO ls_ethnicgroups.
    359.       IF ls_ethnicgroups-fitness IS INITIAL.
    360.         ls_ethnicgroups-fitness = calcu_fitness( ls_ethnicgroups-units ).
    361.         MODIFY ethnicgroups FROM ls_ethnicgroups.
    362.       ENDIF.
    364.       lv_fitnessall =  lv_fitnessall + ls_ethnicgroups-fitness.
    365.     ENDLOOP.
    367.     " 交叉
    368.     DO m * 2 TIMES.
    369.  
    370.       LOOP AT ethnicgroups INTO ls_ethnicgroups.
    371.  
    372.         lv_rate = ls_ethnicgroups-fitness / lv_fitnessall * cross.
    373.         IF lv_rate = 0.
    374.           lv_rate = '0.01'.
    375.         ENDIF.
    376.  
    377.         IF calculat_rate( ) <= lv_rate.
    378.           IF lt_units_fa IS INITIAL.
    379.             lt_units_fa = ls_ethnicgroups-units.
    380.           ELSE.
    381.             lt_units_mo = ls_ethnicgroups-units.
    382.           ENDIF.
    383.         ENDIF.
    384.  
    385.         IF lt_units_fa IS NOT INITIAL AND lt_units_mo IS NOT INITIAL AND lt_units_mo <> lt_units_fa.
    386.           EXIT.
    387.         ENDIF.
    388.  
    389.       ENDLOOP.
    390.  
    391.       IF lt_units_fa IS NOT INITIAL AND lt_units_mo IS NOT INITIAL.
    392.         lt_units_ch = unit_cross( units_fa = lt_units_fa units_mo = lt_units_mo ).
    393.  
    394.         IF lt_units_ch IS NOT INITIAL.
    395.           CLEAR ls_ethnicgroups.
    396.           ls_ethnicgroups-units = lt_units_ch.
    397.           ls_ethnicgroups-index = index.
    398.           index = index + 1.
    399.           APPEND ls_ethnicgroups TO lt_enthicgroups.
    400.         ENDIF.
    401.  
    402.         CLEAR:lt_units_fa,lt_units_mo,lt_units_ch.
    403.       ENDIF.
    404.  
    405.     ENDDO.
    406.  
    407.     " 变异
    408.     LOOP AT ethnicgroups INTO ls_ethnicgroups.
    410.       IF calculat_rate( ) <= variation.
    411.         unit_var( CHANGING units = ls_ethnicgroups-units ).
    412.         ls_ethnicgroups-fitness = calcu_fitness( ls_ethnicgroups-units ).
    413.       ENDIF.
    415.       MODIFY ethnicgroups FROM ls_ethnicgroups.
    416.     ENDLOOP.
    418.     LOOP AT lt_enthicgroups INTO ls_ethnicgroups.
    420.       IF calculat_rate( ) <= variation.
    421.         unit_var( CHANGING units = ls_ethnicgroups-units ).
    422.       ENDIF.
    424.       ls_ethnicgroups-fitness = calcu_fitness( ls_ethnicgroups-units ).
    425.       MODIFY lt_enthicgroups FROM ls_ethnicgroups.
    426.     ENDLOOP.
    428.     " 记录
    429.     CLEAR lt_allgroups.
    430.     MOVE-CORRESPONDING ethnicgroups TO lt_allgroups.
    431.     ls_allgroups-t = curr_t.
    432.     MODIFY lt_allgroups FROM ls_allgroups TRANSPORTING t WHERE units IS NOT INITIAL.
    433.     APPEND LINES OF lt_allgroups TO allgroups.
    434.  
    435.     curr_t = curr_t + 1.
    436.     CLEAR lt_allgroups.
    437.     MOVE-CORRESPONDING lt_enthicgroups TO lt_allgroups.
    438.     ls_allgroups-t = curr_t.
    439.     MODIFY lt_allgroups FROM ls_allgroups TRANSPORTING t WHERE units IS NOT INITIAL.
    440.     APPEND LINES OF lt_allgroups TO allgroups.
    441.  
    442.     APPEND LINES OF lt_enthicgroups TO ethnicgroups.
    443.  
    444.   ENDMETHOD.
    445.  
    446.  
    447. * <SIGNATURE>---------------------------------------------------------------------------------------+
    448. * | Instance Private Method ZCL_GENETIC->RANDOW
    449. * +-------------------------------------------------------------------------------------------------+
    450. * | [--->] LOW                            TYPE        I
    451. * | [--->] HIGH                           TYPE        I
    452. * | [<-()] VALUE                          TYPE        I
    453. * +--------------------------------------------------------------------------------------</SIGNATURE>
    454.   METHOD RANDOW.
    455.  
    456.     DATA: lo_random    TYPE REF TO cl_abap_random,
    457.           lv_seed      TYPE i,
    458.           lv_range_num TYPE i.
    459.  
    460.     lv_seed = cl_abap_random=>seed( ).
    461.     lo_random = cl_abap_random=>create( seed = lv_seed ).
    462.  
    463.     lv_range_num = lo_random->intinrange( low = low high = high ).
    464.  
    465.     value = lv_range_num.
    466.  
    467.   ENDMETHOD.
    468.  
    469.  
    470. * <SIGNATURE>---------------------------------------------------------------------------------------+
    471. * | Instance Private Method ZCL_GENETIC->UNIT_CROSS
    472. * +-------------------------------------------------------------------------------------------------+
    473. * | [--->] UNITS_FA                       TYPE        CHIP_PROPERTY_TAB
    474. * | [--->] UNITS_MO                       TYPE        CHIP_PROPERTY_TAB
    475. * | [<-()] UNITS                          TYPE        CHIP_PROPERTY_TAB
    476. * +--------------------------------------------------------------------------------------</SIGNATURE>
    477.   METHOD unit_cross.
    478.  
    479.     DATA: ls_unit    LIKE LINE OF units,
    480.           ls_unit_fa LIKE LINE OF units,
    481.           ls_unit_mo LIKE LINE OF units,
    482.           ls_var     LIKE LINE OF vars,
    483.           lv_low     TYPE i,
    484.           lv_high    TYPE i.
    485.  
    486.     " 数值运算由于限制无法使用二进制交叉，使用中间数模拟交叉结果
    488.     DO random_up * 2 TIMES.
    490.       LOOP AT units_fa INTO ls_unit_fa.
    491.         READ TABLE units_mo INTO ls_unit_mo WITH KEY name = ls_unit_fa-name.
    492.         READ TABLE vars INTO ls_var WITH KEY name = ls_unit_fa-name.
    494.         lv_low = ls_unit_fa-value.
    495.         IF lv_low > ls_unit_mo-value.
    496.           lv_low  = ls_unit_mo-value.
    497.           lv_high = ls_unit_fa-value.
    498.         ELSE.
    499.           lv_high = ls_unit_mo-value.
    500.         ENDIF.
    502.         IF calculat_rate( ) < '0.5'.
    503.           lv_low = lv_low * 2 - lv_high.
    504.           IF lv_low < 0 .
    505.             lv_low = 0.
    506.           ENDIF.
    507.         ELSE.
    508.           lv_high = lv_high * 2 - lv_low.
    509.         ENDIF.
    511.         IF lv_low < ls_var-low.
    512.           lv_low = ls_var-low.
    513.         ENDIF.
    515.         IF lv_high > ls_var-high.
    516.           lv_high = ls_var-high.
    517.         ENDIF.
    519.         ls_unit-value = randow( low = lv_low high = lv_high ).
    521.         ls_unit-name = ls_unit_fa-name.
    522.         APPEND ls_unit TO units.
    523.         CLEAR: ls_unit_mo, ls_unit_fa.
    524.       ENDLOOP.
    526.       IF check_gen_valid( units ).
    527.         EXIT.
    528.       ENDIF.
    530.       CLEAR units.
    531.     ENDDO.
    533.   ENDMETHOD.
    536. * ---------------------------------------------------------------------------------------+
    537. * | Instance Private Method ZCL_GENETIC->UNIT_VAR
    538. * +-------------------------------------------------------------------------------------------------+
    539. * | [<-->] UNITS                          TYPE        CHIP_PROPERTY_TAB
    540. * +--------------------------------------------------------------------------------------
    541.   METHOD unit_var.
    543.     DATA: ls_unit  LIKE LINE OF units,
    544.           lt_units LIKE units,
    545.           ls_var   LIKE LINE OF vars,
    546.           lv_ind   TYPE sy-index,
    547.           lv_count TYPE i.
    549.     lv_count = lines( units ).
    551.     lv_ind = randow( low = 1 high = lv_count ).
    553.     lt_units = units.
    555.     READ TABLE units INTO ls_unit INDEX lv_ind.
    556.     IF sy-subrc = 0.
    557.       READ TABLE vars INTO ls_var WITH KEY name = ls_unit-name.
    558.       IF sy-subrc = 0.
    559.         DO random_up TIMES.
    561.           ls_unit-value = randow( low = ls_var-low high = ls_var-high ).
    563.           IF check_gen_valid( units ).
    564.             EXIT.
    565.           ENDIF.
    567.           CLEAR units.
    568.         ENDDO.
    569.       ENDIF.
    570.     ENDIF.
    572.     IF units IS INITIAL.
    573.       units = lt_units.
    574.     ENDIF.
    576.   ENDMETHOD.
    577. ENDCLASS.
    对象自定义逻辑版本-接口

     对象自定义逻辑版本-示例1源代码

    1. *----------------------------------------------------------------------*
    2. * 已知
    3. *     0 <= X1 <= 80
    4. *     0 <= X2 <= 40
    5. *     0 <= X3 <= 25
    6. *     15*X1+40*X2+80*X3<=3000
    7. * 求最大值
    8. *     X1*20+30*X2+50*X3
    9. * 备注
    10. *     X1,X2,X3均为整数，如小数可将限制扩大对应倍数
    11. *----------------------------------------------------------------------*
    12.  
    13. CLASS lcl_genetic DEFINITION FINAL  .
    14.  
    15.   PUBLIC SECTION.
    16.  
    17.     INTERFACES zif_gentic_cus .
    18.   PROTECTED SECTION.
    19.   PRIVATE SECTION.
    20. ENDCLASS.
    21.  
    22. CLASS lcl_genetic IMPLEMENTATION.
    23.  
    24.   METHOD zif_gentic_cus~check_gen_valid.
    25.  
    26.     DATA: lv_sum TYPE i.
    27.  
    28.     LOOP AT units INTO DATA(ls_unit).
    29.       CASE ls_unit-name.
    30.         WHEN 'X1'.
    31.           lv_sum = lv_sum + 15 * ls_unit-value.
    32.         WHEN 'X2'.
    33.           lv_sum = lv_sum + 40 * ls_unit-value.
    34.         WHEN 'X3'.
    35.           lv_sum = lv_sum + 80 * ls_unit-value.
    36.         WHEN OTHERS.
    37.       ENDCASE.
    38.  
    39.     ENDLOOP.
    40.  
    41.       IF lv_sum > 3000.
    42.         cv_bool = ''.
    43.       ELSE.
    44.         cv_bool = 'X'.
    45.       ENDIF.
    46.  
    47.   ENDMETHOD.
    48.  
    49.   METHOD zif_gentic_cus~calcu_fitness.
    50.  
    51.     DATA: lv_sum TYPE i.
    52.  
    53.     LOOP AT units INTO DATA(ls_unit).
    54.       CASE ls_unit-name.
    55.         WHEN 'X1'.
    56.           lv_sum = lv_sum + 20 * ls_unit-value.
    57.         WHEN 'X2'.
    58.           lv_sum = lv_sum + 30 * ls_unit-value.
    59.         WHEN 'X3'.
    60.           lv_sum = lv_sum + 50 * ls_unit-value.
    61.         WHEN OTHERS.
    62.       ENDCASE.
    63.     ENDLOOP.
    64.  
    65.       fitness = lv_sum / 10000.
    66.   ENDMETHOD.
    67.  
    68. ENDCLASS.
    69.  
    70. DATA: lo_g    TYPE REF TO zcl_genetic,
    71.       lo_gc   TYPE REF TO lcl_genetic,
    72.       lt_recs TYPE zcl_genetic_base=>tt_allgroups.
    73.  
    74. START-OF-SELECTION.
    75.  
    76.   CREATE OBJECT lo_g TYPE zcl_genetic.
    77.   CREATE OBJECT lo_gc.
    78.  
    79.   lo_g->init( EXPORTING iv_variation = '0.05'
    80.                         iv_cross = '0.8'
    81.                         iv_m = '50'
    82.                         iv_t = '100'
    83.                         iv_random_up = '100'
    84.                         io_genetic_cus = lo_gc
    85.    ).
    86.  
    87.   lo_g->add_var( name = 'X1' low = 0 high = 80 ).
    88.   lo_g->add_var( name = 'X2' low = 0 high = 40 ).
    89.   lo_g->add_var( name = 'X3' low = 0 high = 25 ).
    90.  
    91.   DATA(lt_unit) = lo_g->get_result( ).
    92.   lo_g->get_record( IMPORTING et_rec = lt_recs ).
    93.  
    94.   WRITE:/ '最优解'.
    95.   LOOP AT lt_unit INTO DATA(ls_unit).
    96.     WRITE:/ ls_unit-name, ':' ,ls_unit-value.
    97.   ENDLOOP.
    98.  
    99.   WRITE:/ '迭代过程'.
    100.   SORT lt_recs BY t index.
    101.   LOOP AT lt_recs INTO DATA(ls_rec).
    102.     WRITE:/ '代数:',ls_rec-t,'  适应度:' ,ls_rec-fitness, '  值：'.
    103.     LOOP AT ls_rec-units INTO ls_unit.
    104.       WRITE:ls_unit-name, '-' ,ls_unit-value , ';'.
    105.     ENDLOOP.
    106.   ENDLOOP.

    简单装箱问题实践
    1. *----------------------------------------------------------------------*
    2. * 简化装箱单面填充
    3. * 箱 单面80 * 50
    4. * 物料A 30 10 10    共100个
    5. * 物料B  20 10  5   共200个
    6. * 6种摆放方式
    7. * 1 长宽高
    8. * 2 长高宽
    9. * 3 高长宽
    10. * 4 高宽长
    11. * 5 宽高长
    12. * 6 宽长高
    13. * 预置 3个箱子
    14. *----------------------------------------------------------------------*
    15. DATA: boxx TYPE i VALUE '80',
    16.       boxy TYPE i VALUE '60',
    17.       ax   TYPE i VALUE '30',
    18.       ay   TYPE i VALUE '10',
    19.       az   TYPE i VALUE '100',
    20.       bx   TYPE i VALUE '20',
    21.       by   TYPE i VALUE '10',
    22.       bz   TYPE i VALUE '5',
    23.       amax TYPE i VALUE '100',
    24.       bmax TYPE i VALUE '200'.
    25.  
    26. CLASS lcl_genetic DEFINITION FINAL  .
    27.  
    28.   PUBLIC SECTION.
    29.  
    30.     INTERFACES zif_gentic_cus .
    31.   PROTECTED SECTION.
    32.   PRIVATE SECTION.
    33. ENDCLASS.
    34.  
    35. CLASS lcl_genetic IMPLEMENTATION.
    36.  
    37.   METHOD zif_gentic_cus~check_gen_valid.
    38.  
    39.     DATA: lv_sumx TYPE i,
    40.           lv_sumy TYPE i,
    41.           lv_sumz TYPE i.
    42.  
    43.     LOOP AT units INTO DATA(ls_unit_gr) GROUP BY COND string(  WHEN strlen( ls_unit_gr-name ) > 3 THEN ls_unit_gr-name+2(1) ELSE '' ).
    44.  
    45.       LOOP AT GROUP ls_unit_gr INTO DATA(ls_unit).
    46.         CASE ls_unit-name+0(2).
    47.           WHEN 'A1'.
    48.             lv_sumx = lv_sumx + ax * ls_unit-value.
    49.             lv_sumy = lv_sumy + ay * ls_unit-value.
    50.             lv_sumz = lv_sumz + ay * ls_unit-value.
    51.           WHEN 'A2'.
    52.             lv_sumx = lv_sumx + ax * ls_unit-value.
    53.             lv_sumz = lv_sumz + az * ls_unit-value.
    54.             lv_sumy = lv_sumy + ay * ls_unit-value.
    55.           WHEN 'A3'.
    56.             lv_sumz = lv_sumz + az * ls_unit-value.
    57.             lv_sumx = lv_sumx + ax * ls_unit-value.
    58.             lv_sumy = lv_sumy + ay * ls_unit-value.
    59.           WHEN 'A4'.
    60.             lv_sumz = lv_sumz + az * ls_unit-value.
    61.             lv_sumy = lv_sumy + ay * ls_unit-value.
    62.             lv_sumx = lv_sumx + ax * ls_unit-value.
    63.           WHEN 'A5'.
    64.             lv_sumy = lv_sumy + ay * ls_unit-value.
    65.             lv_sumz = lv_sumz + az * ls_unit-value.
    66.             lv_sumx = lv_sumx + ax * ls_unit-value.
    67.           WHEN 'A6'.
    68.             lv_sumy = lv_sumy + ay * ls_unit-value.
    69.             lv_sumx = lv_sumx + ax * ls_unit-value.
    70.             lv_sumz = lv_sumz + az * ls_unit-value.
    71.           WHEN 'B1'.
    72.             lv_sumx = lv_sumx + bx * ls_unit-value.
    73.             lv_sumy = lv_sumy + by * ls_unit-value.
    74.             lv_sumz = lv_sumz + by * ls_unit-value.
    75.           WHEN 'B2'.
    76.             lv_sumx = lv_sumx + bx * ls_unit-value.
    77.             lv_sumz = lv_sumz + bz * ls_unit-value.
    78.             lv_sumy = lv_sumy + by * ls_unit-value.
    79.           WHEN 'B3'.
    80.             lv_sumz = lv_sumz + bz * ls_unit-value.
    81.             lv_sumx = lv_sumx + bx * ls_unit-value.
    82.             lv_sumy = lv_sumy + by * ls_unit-value.
    83.           WHEN 'B4'.
    84.             lv_sumz = lv_sumz + bz * ls_unit-value.
    85.             lv_sumy = lv_sumy + by * ls_unit-value.
    86.             lv_sumx = lv_sumx + bx * ls_unit-value.
    87.           WHEN 'B5'.
    88.             lv_sumy = lv_sumy + by * ls_unit-value.
    89.             lv_sumz = lv_sumz + bz * ls_unit-value.
    90.             lv_sumx = lv_sumx + bx * ls_unit-value.
    91.           WHEN 'B6'.
    92.             lv_sumy = lv_sumy + by * ls_unit-value.
    93.             lv_sumx = lv_sumx + bx * ls_unit-value.
    94.             lv_sumz = lv_sumz + bz * ls_unit-value.
    95.           WHEN OTHERS.
    96.         ENDCASE.
    97.       ENDLOOP.
    98.  
    99.       IF lv_sumx > 80 OR lv_sumy > 60 OR lv_sumy > 50.
    100.         cv_bool = ''.
    101.       ELSE.
    102.         cv_bool = 'X'.
    103.       ENDIF.
    104.  
    105.     ENDLOOP.
    106.  
    107.   ENDMETHOD.
    108.  
    109.   METHOD zif_gentic_cus~calcu_fitness.
    110.  
    111.     DATA: lv_sum  TYPE i,
    112.           lv_suma TYPE i,
    113.           lv_r    TYPE i.
    114.  
    115.     LOOP AT units INTO DATA(ls_unit_gr) GROUP BY ( name+2(1) = ls_unit_gr-name+2(1) ).
    116.  
    117.       lv_r = ls_unit_gr-name+2(1).
    118.  
    119.       CLEAR lv_suma.
    120.       LOOP AT GROUP ls_unit_gr INTO DATA(ls_unit).
    121.         lv_suma = lv_suma + ls_unit-value.
    122.       ENDLOOP.
    123.  
    124.       lv_sum = lv_sum + lv_suma * lv_r.
    125.     ENDLOOP.
    126.  
    127.     fitness = lv_sum / 10000.
    128.  
    129.   ENDMETHOD.
    130.  
    131. ENDCLASS.
    132.  
    133. DATA: lo_g    TYPE REF TO zcl_genetic,
    134.       lo_gc   TYPE REF TO lcl_genetic,
    135.       lt_recs TYPE zcl_genetic_base=>tt_allgroups.
    136.  
    137. START-OF-SELECTION.
    138.  
    139.   CREATE OBJECT lo_g TYPE zcl_genetic.
    140.   CREATE OBJECT lo_gc.
    141.  
    142.   lo_g->init( EXPORTING iv_variation = '0.05'
    143.                         iv_cross = '0.8'
    144.                         iv_m = '50'
    145.                         iv_t = '100'
    146.                         iv_random_up = '100'
    147.                         io_genetic_cus = lo_gc
    148.    ).
    149.  
    150.   lo_g->add_var( name = 'A11' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ax ) * ( boxy DIV ay )  ) ).
    151.   lo_g->add_var( name = 'A21' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ax ) * ( boxy DIV az )  ) ).
    152.   lo_g->add_var( name = 'A31' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV az ) * ( boxy DIV ax )  ) ).
    153.   lo_g->add_var( name = 'A41' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV az ) * ( boxy DIV ay )  ) ).
    154.   lo_g->add_var( name = 'A51' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ay ) * ( boxy DIV az )  ) ).
    155.   lo_g->add_var( name = 'A61' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ay ) * ( boxy DIV ax )  ) ).
    156.  
    157.   lo_g->add_var( name = 'B11' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bx ) * ( boxy DIV by )  ) ).
    158.   lo_g->add_var( name = 'B21' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bx ) * ( boxy DIV bz )  ) ).
    159.   lo_g->add_var( name = 'B31' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bz ) * ( boxy DIV bx )  ) ).
    160.   lo_g->add_var( name = 'B41' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bz ) * ( boxy DIV by )  ) ).
    161.   lo_g->add_var( name = 'B51' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV by ) * ( boxy DIV bz )  ) ).
    162.   lo_g->add_var( name = 'B61' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV by ) * ( boxy DIV bx )  ) ).
    163.  
    164.  
    165.   lo_g->add_var( name = 'A12' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ax ) * ( boxy DIV ay )  ) ).
    166.   lo_g->add_var( name = 'A22' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ax ) * ( boxy DIV az )  ) ).
    167.   lo_g->add_var( name = 'A32' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV az ) * ( boxy DIV ax )  ) ).
    168.   lo_g->add_var( name = 'A42' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV az ) * ( boxy DIV ay )  ) ).
    169.   lo_g->add_var( name = 'A52' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ay ) * ( boxy DIV az )  ) ).
    170.   lo_g->add_var( name = 'A62' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ay ) * ( boxy DIV ax )  ) ).
    171.  
    172.   lo_g->add_var( name = 'B12' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bx ) * ( boxy DIV by )  ) ).
    173.   lo_g->add_var( name = 'B22' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bx ) * ( boxy DIV bz )  ) ).
    174.   lo_g->add_var( name = 'B32' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bz ) * ( boxy DIV bx )  ) ).
    175.   lo_g->add_var( name = 'B42' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bz ) * ( boxy DIV by )  ) ).
    176.   lo_g->add_var( name = 'B52' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV by ) * ( boxy DIV bz )  ) ).
    177.   lo_g->add_var( name = 'B62' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV by ) * ( boxy DIV bx )  ) ).
    178.  
    179.  
    180.   lo_g->add_var( name = 'A13' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ax ) * ( boxy DIV ay )  ) ).
    181.   lo_g->add_var( name = 'A23' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ax ) * ( boxy DIV az )  ) ).
    182.   lo_g->add_var( name = 'A33' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV az ) * ( boxy DIV ax )  ) ).
    183.   lo_g->add_var( name = 'A43' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV az ) * ( boxy DIV ay )  ) ).
    184.   lo_g->add_var( name = 'A53' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ay ) * ( boxy DIV az )  ) ).
    185.   lo_g->add_var( name = 'A63' low = 0 high = nmax( val1 = amax val2 = ( boxx DIV ay ) * ( boxy DIV ax )  ) ).
    186.  
    187.   lo_g->add_var( name = 'B13' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bx ) * ( boxy DIV by )  ) ).
    188.   lo_g->add_var( name = 'B23' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bx ) * ( boxy DIV bz )  ) ).
    189.   lo_g->add_var( name = 'B33' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bz ) * ( boxy DIV bx )  ) ).
    190.   lo_g->add_var( name = 'B43' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV bz ) * ( boxy DIV by )  ) ).
    191.   lo_g->add_var( name = 'B53' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV by ) * ( boxy DIV bz )  ) ).
    192.   lo_g->add_var( name = 'B63' low = 0 high = nmax( val1 = bmax val2 = ( boxx DIV by ) * ( boxy DIV bx )  ) ).
    193.  
    194.   DATA(lt_unit) = lo_g->get_result( ).
    195.   lo_g->get_record( IMPORTING et_rec = lt_recs ).
    196.  
    197.   WRITE:/ '最优解'.
    198.   LOOP AT lt_unit INTO DATA(ls_unit).
    199.     WRITE:/ ls_unit-name, ':' ,ls_unit-value.
    200.   ENDLOOP.
    201.  
    202.   WRITE:/ '迭代过程'.
    203.   SORT lt_recs BY t index.
    204.   LOOP AT lt_recs INTO DATA(ls_rec).
    205.     WRITE:/ '代数:',ls_rec-t,'  适应度:' ,ls_rec-fitness, '  值：'.
    206.     LOOP AT ls_rec-units INTO ls_unit.
    207.       WRITE:ls_unit-name, '-' ,ls_unit-value , ';'.
    208.     ENDLOOP.
    209.   ENDLOOP.
  • 相关阅读:
    lua学习
    FPGA的主流技术与市场表现方面的调研报告
    【Docker系列】Docker-核心概念/常用命令与项目部署实践
    【HDLBits 刷题】Verilog Language（4）Procedures 和 More Verilog Features 部分
    Impala入门案例
    自动驾驶学习笔记（六）——Apollo安装
    uboot引导应用程序
    TCP/IP(七)TCP的连接管理(四)全连接
    无纸化办公小程序数据交互、wxs的使用
    使用Python编写一个多线程的12306抢票程序
  • 原文地址：https://blog.csdn.net/xiefireworks/article/details/137876522