• ENVI_IDL: 批量制作专题地图

    目录

    1. 提要

    2. 编程 

    1. 提要

    —————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————

    说实话，这个ENVI_IDL的批量制图是真的不好用，看个人吧。另外大量的函数解释需要自己去看help，代码里面我只是简单的解释了一下每个函数的重要参数，如果有其它需要，可以自行查找。

    还有，后面的指北针由于idl没有内置，所以需要自己下一个指北针然后贴到图上去。以及比例尺idl也没有自己内置，需要借用colorbar()函数想想办法。

    还有一件事就是里面的城市的标签需要自己一个一个去指定位置，费时费力，但是一次弄好了之后循环就不需要老自己弄了。

    所以说，前面的格网和colorbar以及字体的相关设置等等已经能够满足大部分需求。

    最后，保存可以自己挑选合适的图片格式，如png、tiff、svg等等

    ————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————— 

    2. 编程 

    1. pro week_eleven_study1
    2.   ; 如何批量制图
    3.   
    4.   ; tiff文件的路径
    5.   tiff_dir = 'D:/IDL_program/experiment_data/chapter_6/TROPOMI_NO2/'
    6.   
    7.   ; 获取所有tiff文件的路径
    8.   tiff_path_list = file_search(tiff_dir, '*.tiff', count=tiff_count)
    9.   ; 获取所有tiff文件的名称
    10.   tiff_name_list = file_basename(tiff_path_list, '.tiff')
    11.   
    12.   ; 获取shp文件的路径
    13.   china_path = 'D:/IDL_program/experiment_data/chapter_6/shp_file/china_province.shp'
    14.   sichuan_path = 'D:/IDL_program/experiment_data/chapter_6/shp_file/Sichuan_city_wgs84.shp'
    15.   ; 据说使用beijing54坐标系有时会出现无法识别的现象，所以这里的shp文件是wgs84坐标系的
    16.   
    17.   
    18.   ; 循环制图
    19.   for tiff_i = 0, tiff_count - 1 do begin
    20.     ; 获取该循环下的tiff文件的数据以及地理信息
    21.     data = read_tiff(tiff_path_list[tiff_i], geotiff=geo_info)
    22.     ; 输出路径
    23.     out_path = tiff_dir + tiff_name_list[tiff_i] + '.png'
    24.     
    25.     ; 获取data的size
    26.     data_size = size(data)
    27.     ; 获取数据的行列数
    28.     data_col = data_size[1]
    29.     data_row = data_size[2]
    30.     ; 获取图像数据的分辨率
    31.     resolution = geo_info.(0)
    32.     resolution_x = resolution[0]
    33.     resolution_y = resolution[1]
    34.     ; 获取图像数据的角点信息
    35.     geo_loc = geo_info.(1)
    36.     ; 最大最小经纬度
    37.     lon_min = geo_loc[3]
    38.     lat_max = geo_loc[4]
    39.     lon_max = lon_min + data_col * resolution_x
    40.     lat_min = lat_max - data_row * resolution_y
    41.     
    42.     ; 制图——》主要是image函数(我的意见是多看help)
    43.     im = image($
    44.       ; 为了方便解释，我会分行写代码并解释
    45.  
    46.       ; 首先传入制图需要的主体数据
    47.       data,$
    48.       $  
    49.       ; 然后由于图像是黑白但是有灰度值，所以这里我们给他整个彩色
    50.       rgb_table=22,$  ; 你可以写颜色渐变的代号(help里面有),也可以直接传入颜色字符串(譬如'red')
    51.         
    52.       ; 但是你可以发现这个颜色渐变有点离谱的那种感觉,所以你可能会想到去2%线性拉伸
    53.       ; 但是没有必要，image()函数内置了min_value和max_value供您集中颜色
    54.       min_value=0.0, max_value=0.002,$  ; 这些最大最小基于你自己在arcgis抑或envi查看得到(当然你可以写代码按某种2%的规则寻找)
    55.         
    56.       ; 由于我们的image函数是从下往上绘制图像，所以我们得到的图像是颠倒的，所以需要纠正
    57.       /order,$
    58.         
    59.       ; 投影信息
    60.       map_projection='Geographic',$  ; 你知道你的投影是什么之后去help查看输入即可
    61.       ; 除此之外，你还应该告诉函数你的投影信息的单位是什么
    62.       grid_units='degrees',$  ; 当然你也可以输入代号2(具体查看help)
    63.         
    64.       ; 但是只有上面的信息是不够的，函数不知道我们数据的地理位置，就算知道了投影也不知道把图片放在哪里
    65.       ; 所以还需要告诉函数图像数据的位置(其实是告诉函数左下角点的经纬度)
    66.       image_location=[lon_min, lat_min],$
    67.       ; 另外，你还需要告诉函数x、y方向上跨越的经纬度度数(或者说是图像的尺寸)
    68.       image_dimension=[lon_max - lon_min, lat_max - lat_min],$  ; 宽度和高度
    69.       
    70.       ; 上面是设置图像的大小尺寸，现在图像是要放在一个窗口中显示的，所以这里还需要设置一下窗口的大小(当然你不设置也是有默认的参数)
    71.       dimension=[1000, 1000],$
    72.         
    73.       ; 另外有时候我们不需要那么大的图像显示在窗口中，那么我们可以通过输入最大最小经纬度限制显示的范围(这里我们设定只需要四川范围)
    74.       limit=[25, 97.0, 35.0, 109.0],$  ; [Latmin, Lonmin, Latmax, Lonmax]
    75.       
    76.       ; 可能你现在会觉得四川范围的图像在窗口中显示的太小了，需要将图像在窗口中显示的大一些
    77.       position=[0.05, 0.05, 0.95, 0.95])  ; [左下角点x、左下角点y、右上角点x、右上角点y]
    78.       ; 这里传入的是图像左下角点和右上角点的坐标,这个坐标是图像的经纬度坐标，而是基于整个窗口的坐标，以窗口左下角点为(0, 0),右上角点为(1, 1)
    79.       ; 那么去设置图像的左下角点和右上角点的坐标，就可以确定整幅图像在窗口的显示大小以及位置了
    80.       ; 另外你可能会疑惑，我的图像长宽不是1：1，那么上面这样子会不会做拉伸处理，是不会的，函数会基于你给定的位置尽量靠近这个位置并放大，但是不会拉伸
    81.         
    82.     ; 现在设置好了image参数，可以往里面添加一些shp文件(不然孤零零的在那里一张图谁知道那地方是哪里啊)
    83.     m1 = mapcontinents(china_path, color='black', linestyle='-:', thick=0.8)  ; 传入shp文件的路径(必须)
    84.     ; 当然你也可以设置线的颜色color(不设置默认黑色)、线的样式linestyle(默认细实线)、设置线的厚度thick(当然还有一些其它的参数这里就不再一一介绍)
    85.     m2 = mapcontinents(sichuan_path, color='black', linestyle='-', thick=1.8)
    86.     
    87.     ; 由于上面position我们知道函数是尽量在我们设置的位置放置图像，但是为了后续加上坐标轴之类的，那么我们就需要图像在窗口中的坐标位置了
    88.     true_position = im.position
    89.     position_dl_x = true_position[0]
    90.     position_dl_y = true_position[1]
    91.     position_ur_x = true_position[2]
    92.     position_ur_y = true_position[3]
    93.     
    94.     
    95.     ; 标题的相关设置
    96.     ; 标题名称
    97.     im.title = 'TROPOMI NO$_2$  result  over  Sichuan area'  ; 其中$$中间表示对其中的字符串进行特殊操作，这里_表示2是下标
    98.     ; 标题的字体
    99.     im.title.font_name = 'palatino'  ; 字体有哪些可以去help搜索font即可得到答案
    100.     ; 字体的大小
    101.     im.title.font_size = 16  ; 这个自己多试几下就知道字的大小了
    102.     ; 字体颜色
    103.     im.title.font_color = 'black'  ; 这里既可以传入颜色字符串，也可以传入RGB三个数字(以数组形式),更可以传入颜色的代称(但是不是1、2诸如此类，而是#加一些数字，具体代表什么颜色看help)
    104.     ; 字体的粗细
    105.     im.title.font_style = 3  ; 表示粗体(0-正常\2-斜体\3-斜粗体)，另外也可以传入字符串达到相同的效果，具体看help
    106.     
    107.     
    108.     ; 格网的相关设置
    109.     ; 格网对象设置(其实前面标题也是可以这样设置，如果你学过诸如python之类面向对象语言，那么相信这是很容易理解的)
    110.     grid = im.mapgrid
    111.     ; 我们看图片可以发现，经纬度显示在格网的线上，而不是在图的侧边，为了我们的视觉习惯，我们可以更改
    112.     grid.label_position = 0  ; 其实这里你可以设置[0,1](闭区间)、0表示最靠左最靠下，1表示最靠右最靠上，处于中间按比例靠近
    113.     ; 因为这里有每一条经纬线的标签，所以也是可以有字体的相关设置的
    114.     grid.font_name = 'schoolbook'  ; 我随便在help挑的一种字体
    115.     grid.font_size = 8  ; 这个在轴上显示的应该比上面的title下一点才是
    116. ;    grid.font_color = 'black'  ; 我只是告诉大家这个也是有的，都是相通的，其实不写默认也是黑色的(我错了，这个是没有的，所以大家要多多尝试，勇于犯错)
    117.     grid.font_style = 'bi'  ; 这里是告诉，上面可以使用1、2类似的数字，这里使用字符串也是可以达到相同的效果(bi是粗体斜体)
    118.     ; 设置格网线的样式(我们觉得这个格网线是实线有点喧宾夺主，所以换成虚线会比较好一点)
    119.     grid.linestyle = '-.'  ; __表示虚线，其它还有一些表示可以自行查看·help
    120.     ; 对于格网的最外边的一圈线，我们觉得粗细不对，应该再设置的粗一点，不应当和里面的线是虚线而且那么细
    121.     grid.horizon_thick = 2  ; 我们如果设置了这个那么会将horizon line(最外圈的线)更改为实线,如果你还有修改horizon line的需求，可以指定grid.horizon_linestyle
    122.     ; 得到经度标签的对象
    123.     lons = grid.longitudes
    124.     lats = grid.latitudes
    125.     ; 我们的x轴的标签是竖着的，我们希望是横着的(由于lons是对象类型的数组，里面是每一个标签对象,所以需要循环)
    126.     for lon_i = 0, n_elements(lons) - 1 do lons[lon_i].label_angle = 0.0  ; 旋转角度是0表示没有旋转就是横着的
    127.     for lat_i = 0, n_elements(lats) - 1 do lats[lat_i].label_angle = 90.0  ; 另外我们希望y轴的标签是竖着的，所以旋转角度是90°
    128.     ; 另外我们发现在原点处的标签重合了，所以我们需要再设置一下标签的对齐方式(默认是居中对齐)(其实这个可以写到上面循环中去)
    129.     for lon_i = 0, n_elements(lons) - 1 do lons[lon_i].label_align = 0.0  ; 0.0表示左对齐，0.5表示中间对齐，1.0表示右对齐，其它0-1的数字按比例对齐
    130.     for lat_i = 0, n_elements(lats) - 1 do lats[lat_i].label_align = 0.0
    131.     ; 然后还有就是x轴和y轴最后一个表示经纬度的标签有点多余，我们需要将其隐藏
    132.     lons[-1].label_show = 0  ; 0表示隐藏
    133.     lats[-1].label_show = 0  ; -1表示最后一个数字
    134.     
    135.     ; 另外我们希望在指定的位置写上地名之类的东西，那么这个在idl是比较麻烦的，好像目前没有别的办法
    136.     ; 这里解释第一个:首先传入经纬度(先x轴坐标再y轴坐标，然后传入需要填写的值，在之后传入填写的位置,在后面的参数就是微调)
    137.     t=text(103.3d,30.46d,'Chengdu',/data,$
    138.       font_name='Palatino',font_size=12, font_style=1)  ; 省会城市我们让其粗体好了
    139.     t=text(101.8d,31.8d,'Aba',/data,$
    140.       font_name='Palatino',font_size=12)
    141.     t=text(100.1d,31.5d,'Ganzi',/data,$
    142.       font_name='Palatino',font_size=12)
    143.     t=text(101.6d,27.65d,'Liangshan',/data,$
    144.       font_name='Palatino',font_size=12)
    145.     t=text(101.1d,26.7d,'Panzhihua',/data,$
    146.       font_name='Palatino',font_size=12)
    147.     t=text(102.5d,29.8d,'Yaan',/data,$
    148.       font_name='Palatino',font_size=12)
    149.     t=text(104.0d,30.93d,'Deyang',/data,$
    150.       font_name='Palatino',font_size=12)
    151.     t=text(104.1d,31.6d,'Mianyang',/data,$
    152.       font_name='Palatino',font_size=12)
    153.     t=text(105.2d,28.65d,'Luzhou',/data,$
    154.       font_name='Palatino',font_size=12)
    155.     t=text(103.4d,29.8d,'Meishan',/data,$
    156.       font_name='Palatino',font_size=12)
    157.     t=text(104.75d,30.05d,'Ziyang',/data,$
    158.       font_name='Palatino',font_size=12)
    159.     t=text(104.5d,29.7d,'Neijiang',/data,$
    160.       font_name='Palatino',font_size=12)
    161.     t=text(104.3d,29.15d,'Zigong',/data,$
    162.       font_name='Palatino',font_size=12)
    163.     t=text(104.4d,28.5d,'Yibin',/data,$
    164.       font_name='Palatino',font_size=12)
    165.     t=text(105.0d,30.6d,'Suining',/data,$
    166.       font_name='Palatino',font_size=12)
    167.     t=text(105.7d,30.88d,'Nanchong',/data,$
    168.       font_name='Palatino',font_size=12)
    169.     t=text(107.2d,31.3d,'Dazhou',/data,$
    170.       font_name='Palatino',font_size=12)
    171.     t=text(106.1d,30.25d,'Guangan',/data,$
    172.       font_name='Palatino',font_size=12)
    173.     t=text(106.5d,31.95d,'Bazhong',/data,$
    174.       font_name='Palatino',font_size=12)
    175.     t=text(105.3d,32.2d,'Guangyuan',/data,$
    176.       font_name='Palatino',font_size=12)
    177.     t=text(103.4d,29.3d,'Leshan',/data,$
    178.       font_name='Palatino',font_size=12)
    179.     
    180.     ; 另外还有城市的symbol，图形符号也搞一个(当然，这个也是费时费力)
    181.     s=symbol(104.06d,30.67d,'circle',/data,$
    182.       sym_size=0.5,sym_color='black',sym_thick=2)  ; 成都的符号就粗一点把
    183.     s=symbol(101.72d,31.93d,'circle',/data,$
    184.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    185.     s=symbol(99.96d,31.64d,'circle',/data,$
    186.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    187.     s=symbol(102.27d,27.90d,'circle',/data,$
    188.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    189.     s=symbol(101.72d,26.58d,'circle',/data,$
    190.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    191.     s=symbol(103.00d,29.98d,'circle',/data,$
    192.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    193.     s=symbol(104.38d,31.13d,'circle',/data,$
    194.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    195.     s=symbol(104.73d,31.47d,'circle',/data,$
    196.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    197.     s=symbol(105.43d,28.87d,'circle',/data,$
    198.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    199.     s=symbol(103.83d,30.05d,'circle',/data,$
    200.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    201.     s=symbol(104.65d,30.12d,'circle',/data,$
    202.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    203.     s=symbol(105.05d,29.58d,'circle',/data,$
    204.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    205.     s=symbol(104.78d,29.35d,'circle',/data,$
    206.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    207.     s=symbol(104.62d,28.77d,'circle',/data,$
    208.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    209.     s=symbol(105.57d,30.52d,'circle',/data,$
    210.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    211.     s=symbol(106.08d,30.78d,'circle',/data,$
    212.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    213.     s=symbol(107.50d,31.22d,'circle',/data,$
    214.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    215.     s=symbol(106.63d,30.47d,'circle',/data,$
    216.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    217.     s=symbol(106.77d,31.85d,'circle',/data,$
    218.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    219.     s=symbol(105.83d,32.43d,'circle',/data,$
    220.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    221.     s=symbol(103.77d,29.57d,'circle',/data,$
    222.       sym_size=0.5,sym_color='black',sym_thick=1.5)
    223.       
    224.     ; 现在图还缺一点什么呢？对了，还有图例没有
    225.     cb = colorbar(/data, target=im)
    226.     ; 由于空间有限，所以我们需要将图标移动到左下角的位置(上面colorbar函数默认显示在图的正底下)
    227.     cb.position = [position_dl_x + 0.5, position_dl_y - 0.07, position_ur_x, 0.09]  ; 这个需要自己慢慢调
    228.     ; 另外图例的数字位数太多，也需要调整一下
    229.     cb.range = [0.00, 1.00]
    230.     ; 做好了图标总要告诉人家这个图标是什么吧？还缺个标题或者说是单位，我们前面将0.001改为了1.0，所以要有标题提醒10^-3
    231.     cb.title = 'NO$_2$ ($\times$10$^{-3}$ mol / m$^2$)'  ; ✖是特殊符号，help里面有对应的写法，这里\times表示乘号
    232.     cb.font_style = 2  ; 设置为斜体
    233.     
    234.     ; 另外还有城市图标那个图例没有弄
    235.     s=symbol(position_dl_x+0.2,position_dl_y-0.07,'circle',target=im,$
    236.       sym_size=0.6,sym_color='black',sym_thick=1.5)
    237.     t=text(position_dl_x+0.21,position_dl_y-0.07,'City center',target=im,$
    238.       font_name='Palatino',font_size=12)
    239.     
    240.     
    241.     ; 保存图片
    242.     im.save, out_path
    243.     ; 关闭弹出的图片
    244.     im.close
    245.   print
    246.   endfor
    247. end

    —————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————

    这是运行结果：

    这是循环得到的三张图片：
     

     

    分辨率还是非常高的：

     

    这是其中一张图片：


     

     

    —————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————————

     

    我是炒茄子，不用谢·1

  • 相关阅读:
    最高检：聚焦金融、电信、互联网等领域 打击泄露个人信息违法犯罪
    从token中获取用户信息
    【编解码】解码字符串中的 UNICODE 字符
    《数据结构》队列
    rust打包编译为mac或者linux可执行文件，发送到别的电脑不能运行
    Go | 函数注意事项
    springboot多环境配置
    中小企业平台安全建设如何落地
    教你从零开始画echarts地图
    ansible fetch 模块
  • 原文地址：https://blog.csdn.net/m0_63001937/article/details/125904969