学习太极创客 — MQTT 第二章（八）ESP8266 MQTT 用户密码认证

视频链接：https://www.bilibili.com/video/BV1fK4y1L72n?spm_id_from=333.999.0.0&vd_source=b91967c499b23106586d7aa35af46413

资料链接：http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-tuttorial/mqtt-tutorial/mqtt-user-auth/

在课程中，通过 MQTT.fx 这个软件一直使用的是然也物联的服务端（“test.ranye-iot.net”），然也物联的服务端可以不要求客户端提供用户名和密码。但是在有些情况下，比如个人搭建的属于自己的 MQTT 服务器，为了保护服务端不会被别人所使用，就需要增加用户名和密码了。

除了上述提到的作用之外，服务端还可以利用用户名和密码来管理客户端，因为通常情况下，对于 MQTT 服务器来说，有可能很多用户同时在使用服务器，但对于不同用户来说，他们都有各自的客户端，这些各自的、私人的客户端可能会使用一些私人的 MQTT 资源，比如说某些 MQTT 主题可能专门属于某个用户。

也就是说对于服务端和客户端来说，用户名和密码有双向的作用。因为本教程的重点是如何使用 MQTT 协议在客户端中如何进行开发，并没有涉及到服务端的开发内容，所以在服务端如何设置用户名和密码的操作是不讲解的。

下面，通过 MQTT.fx 这个软件来说一下如何进行设置。

1、MQTT.fx 用户密码认证

然也物联提供了一个测试用的用户名和密码，用户名是 test-user ，密码是 ranye-iot

下面，故意将用户名或者密码给输入错误，

再点击登录后，会提示没有权限。

另外需要说明一点的是，作为测试用户来说，所能订阅的主题和发布的主题是有一些限制的，只能订阅和发布以 用户名级别下的任何的主题。

比如，直接发布或者订阅不在 test-user/ 下的主题时，如下图所示。

虽然可以订阅成功，

但是当通过该主题发布消息时，订阅该主题的客户端是接收不到任何消息的。

我们再试试使用 test-user/ 下的主题来发布消息，

需要注意，

2、 ESP8266 MQTT 用户密码认证

以下示例程序实现了 ESP8266 连接 MQTT 服务端时的用户名和密码认证。

程序中的在调用 connect 函数时，提供了MQTT服务端连接的用户名和密码信息。

这个示例程序中的主题内容与前面介绍的 1-6 节 ESP8266 发布 MQTT 消息一样，只不过是多了连接 MQTT 服务端时的用户名和密码信息。

/**********************************************************************
项目名称/Project          : 零基础入门学用物联网
程序名称/Program name     : pub_password_auth_ranye
团队/Team                : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)
作者/Author              : CYNO朔
日期/Date（YYYYMMDD）     : 20201227
程序目的/Purpose          : 
本程序旨在演示如何使用PubSubClient库使用ESP8266向MQTT服务器发布信息。
发布信息中，服务器通过用户名和密码进行认证。
-----------------------------------------------------------------------
本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。
该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：
http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-c/esp8266-nodemcu-web-client/http-request/
***********************************************************************/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <Ticker.h>
 
// 设置wifi接入信息(请根据您的WiFi信息进行修改)
const char* ssid = "FAST_153C80";
const char* password = "123456798";
const char* mqttServer = "test.ranye-iot.net";
// 如以上MQTT服务器无法正常连接，请前往以下页面寻找解决方案
// http://www.taichi-maker.com/public-mqtt-broker/
 
// MQTT服务端连接用户名密码
const char* mqttUserName = "test-user";
const char* mqttPassword = "ranye-iot";
 
Ticker ticker;
WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);
 
int count;    // Ticker计数用变量
 
void setup() {
  Serial.begin(9600);
 
  // Ticker定时对象
  ticker.attach(1, tickerCount);
  
  //设置ESP8266工作模式为无线终端模式
  WiFi.mode(WIFI_STA);
  
  // 连接WiFi
  connectWifi();
  
  // 设置MQTT服务器和端口号
  mqttClient.setServer(mqttServer, 1883);
 
  // 连接MQTT服务器
  connectMQTTServer();
}
 
void loop() {
  // 如果开发板未能成功连接服务器，则尝试连接服务器
  if (!mqttClient.connected()) {
    connectMQTTServer();
  }
  
   mqttClient.loop();
  // 每隔3秒钟发布一次信息
  if (count >= 3){
    pubMQTTmsg();
    count = 0;
  }
}
 
void tickerCount(){
  count++;
}
 
void connectMQTTServer(){
  // 根据ESP8266的MAC地址生成客户端ID（避免与其它ESP8266的客户端ID重名）
  String clientId = "esp8266-" + WiFi.macAddress();
 
  // 连接MQTT服务器。此处使用了程序首部定义的用户名和密码来实现MQTT服务端认证
  if (mqttClient.connect(clientId.c_str(), mqttUserName, mqttPassword)) { 
    Serial.println("MQTT Server Connected.");
    Serial.print("Server Address: ");
    Serial.println(mqttServer);
    Serial.print("ClientId: ");
    Serial.println(clientId);
  } else {
    Serial.print("MQTT Server Connect Failed. Client State:");
    Serial.println(mqttClient.state());
    delay(3000);
  }   
}
 
// 发布信息
void pubMQTTmsg(){
  static int value;
 
  // 建立发布主题。主题名称以taichi/Pub-为前缀，后面添加设备的MAC地址。
  // 这么做是为确保不同用户进行MQTT信息发布时，ESP8266客户端名称各不相同，
  String topicString = "test-user/Pub-" + WiFi.macAddress();
  char publishTopic[topicString.length() + 1];  
  strcpy(publishTopic, topicString.c_str());
 
  // 建立发布信息。信息内容以Hello World为起始，后面添加发布次数。
  String messageString = "Hello World " + String(value++); 
  char publishMsg[messageString.length() + 1];   
  strcpy(publishMsg, messageString.c_str());
 
  // 实现ESP8266向主题发布信息
  if(mqttClient.publish(publishTopic, publishMsg)){
    Serial.println("Publish Topic:");Serial.println(publishTopic);
    Serial.println("Publish message:");Serial.println(publishMsg);      
  } else {
    Serial.println("Message Publish Failed."); 
  }
}
 
// ESP8266连接wifi
void connectWifi(){
 
  WiFi.begin(ssid, password);
 
  //等待WiFi连接,成功连接后输出成功信息
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi Connected!");  
  Serial.println(""); 
}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128

程序运行逻辑是在通过用户名和密码连接到 MQTT 服务器后，每隔 3 秒钟向主题 （“test-user/Pub-” + WiFi.macAddress()）发布一次信息，消息内容为 "Hello World " + String(value++);

运行程序后，打开串口监视器。

程序重点在连接 MQTT 服务器时，用户名和密码作为参数传入函数 connect 中。

// MQTT服务端连接用户名密码
const char* mqttUserName = "test-user";
const char* mqttPassword = "ranye-iot";
1
2
3

打开 MQTT.fx 软件（因为是作为订阅者，所以设置不设置账号和密码都可以（原因是在服务器端没有设置订阅用户的权限）），并且订阅该主题。

输出结果如下，