学习太极创客 — MQTT（四）服务端连接操作

视频链接：https://www.bilibili.com/video/BV1T54y1k7MQ/?spm_id_from=trigger_reload&vd_source=b91967c499b23106586d7aa35af46413

教程链接：http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-tuttorial/mqtt-tutorial/client-connect-mqtt-server/

MQTT 服务端连接操作

电脑客户端连接 MQTT 服务端

首先，我们一起来学习如何使用电脑软件来实现客户端与服务端的连接。我们将为电脑安装一款免费的MQTT客户端软件 – MQTTfx。

官网最新版需要注册码，否则用不了，直接安装太极串口提供的 1.7.1 版本。

操作过程看视频。

在传输过程中如果需要加密的话，就使用 TCP/TLS 端口：8883.

ESP8266 连接 MQTT 服务端

ESP8266 的 Arduino 开发环境里有多个 MQTT 库，我们将使用最为流行的 PubSubClient 库来实现 MQTT 物联网应用。

/**********************************************************************
项目名称/Project          : 零基础入门学用物联网
程序名称/Program name     : connect_mqtt_server
团队/Team                : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)
作者/Author              : CYNO朔
日期/Date（YYYYMMDD）     : 20201109
程序目的/Purpose          : 
本程序旨在演示如何使用PubSubClient库使用ESP8266向连接MQTT服务器。
-----------------------------------------------------------------------
本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。
该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：
http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/iot-c/esp8266-nodemcu-web-client/http-request/
***********************************************************************/
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
 
// 设置wifi接入信息(请根据您的WiFi信息进行修改)
const char* ssid = "FAST_153C80";
const char* password = "123456798";
const char* mqttServer = "test.ranye-iot.net";
 
// 如以上MQTT服务器无法正常连接，请前往以下页面寻找解决方案
// http://www.taichi-maker.com/public-mqtt-broker/
 
WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);
 
void setup() {
  Serial.begin(9600);
 
  //设置ESP8266工作模式为无线终端模式
  WiFi.mode(WIFI_STA);
  
  // 连接WiFi
  connectWifi();
  
  // 设置MQTT服务器和端口号
  mqttClient.setServer(mqttServer, 1883);
 
  // 连接MQTT服务器
  connectMQTTServer();
}
 
void loop() { 
  if (mqttClient.connected()) { // 如果开发板成功连接服务器    
    mqttClient.loop();          // 保持客户端心跳
  } else {                  // 如果开发板未能成功连接服务器
    connectMQTTServer();    // 则尝试连接服务器
  }
}
 
void connectMQTTServer(){
  // 根据ESP8266的MAC地址生成客户端ID（避免与其它ESP8266的客户端ID重名）
  String clientId = "esp8266-" + WiFi.macAddress();
 
  // 连接MQTT服务器
  if (mqttClient.connect(clientId.c_str())) { 
    Serial.println("MQTT Server Connected.");
    Serial.println("Server Address: ");
    Serial.println(mqttServer);
    Serial.println("ClientId:");
    Serial.println(clientId);
  } else {
    Serial.print("MQTT Server Connect Failed. Client State:");
    Serial.println(mqttClient.state());
    delay(3000);
  }   
}
 
// ESP8266连接wifi
void connectWifi(){
 
  WiFi.begin(ssid, password);
 
  //等待WiFi连接,成功连接后输出成功信息
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi Connected!");  
  Serial.println(""); 
}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

运行结果如下：

1、注意程序中的

WiFi.status()
1

在前面说过，当客户端向服务器端发送连接请求之后，服务器端接收到请求以后，会返回一个数据包 CONNACK ，这个 CONNACK 数据包中的信息内容如下，

有两个，一个是 sessionPresent ，一个是 returnCode 。这个 returnCode 正是程序中 status 函数的返回值。

2、注意程序中的

void loop() { 
  if (mqttClient.connected()) { // 如果开发板成功连接服务器    
    mqttClient.loop();          // 保持客户端心跳
  } else {                  // 如果开发板未能成功连接服务器
    connectMQTTServer();    // 则尝试连接服务器
  }
}
1
2
3
4
5
6
7

mqttClient.loop(); 是保持客户端心跳。这个函数要被确保经常性的被调用（不要加 delay 函数）。

3、可能会有疑惑，就是连接 MQTT 服务器时

mqttClient.connect(clientId.c_str()
1

根据前面所说要发送 CONNECT 报文，

在这个报文中，有三个参数是必须要的，但是程序中却只有一个，即 clientId ，这是为什么呢？

事实上是另外的这两个参数有默认值，即 cleanSession = true ，keepAlive = 15。