手写简易操作系统(九)--实现打印函数

前情提要

前面我们已经进入内核程序了，中间穿插了一点特权级的知识，现在我们开始准备一个打印函数

很不幸，还有汇编程序

一、C调用规约

因为涉及到C与汇编的联合编程，我们这里简述一下调用规约，调用规约就是约定参数压栈顺序问题，还有栈空间的清理工作。

真的是有很多种调用规约，因为是简述，我们举个我们用到的cdecl的例子。

函数

int subtract(int a, int b);  //被调用者
int sub = subtract (3,2);    // 主调用者
1
2

主调用者，从右到左压栈，回收栈空间

push     2                         ;压入参数b      
push     3                         ;压入参数a 
call subtract                      ;调用函数subtract 
add esp, 8                         ;回收（清理）栈空间
1
2
3
4

被调用者保存寄存器，返回值放在EAX中

push ebp                     ;压入ebp备份
mov ebp,esp                  ;将esp赋值给ebp
mov eax,[ebp+0x8]            ;偏移8字节处为第1个参数a 
add eax,[ebp+0xc]            ;偏移0xc字节处是第2个参数b
mov esp,ebp                  ;为防止中间有入栈操作，用ebp恢复esp        
pop  ebp                     ;将ebp恢复
ret 
1
2
3
4
5
6
7

二、显卡的端口控制

VGA中的寄存器可以分为

这些只是寄存器的分组，实际上比这个要多很多。

CRT controller寄存器组的端口地址被设置为0x3Bx，Address Register和Data Register的端口地址实际值为3B4h-3B5h。并且为了兼容monochrome 适配器（显卡），Input Status #1 Register寄存器的端口地址被设置为0x3BA。

三、打印单个字符

我们创建一个 put_char 函数

; os/src/lib/kernel/print.s
TI_GDT equ  0
RPL0  equ   0
SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0

[bits 32]
section .text
global put_char
put_char:
    pushad	                    ; 备份32位寄存器环境
    mov ax, SELECTOR_VIDEO	    ; 不能直接把立即数送入段寄存器
    mov gs, ax                  ; 所以每次都要给视频段选择子赋值，避免错误

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;获取光标位置
    ;先获得高8位
    mov dx, 0x03d4              ;索引寄存器
    mov al, 0x0e	            ;用于提供光标位置的高8位
    out dx, al
    mov dx, 0x03d5              ;通过读写数据端口0x3d5来获得或设置光标位置 
    in al, dx	                ;得到了光标位置的高8位
    mov ah, al

    ;再获取低8位
    mov dx, 0x03d4
    mov al, 0x0f
    out dx, al
    mov dx, 0x03d5 
    in al, dx

    ;将光标存入bx
    mov bx, ax	  
    ;下面这行是在栈中获取待打印的字符
    mov ecx, [esp + 36]	      ;pushad压入4×8＝32字节,加上主调函数的返回地址4字节,故esp+36字节
    cmp cl, 0xd				  ;CR是0x0d,LF是0x0a
    jz .is_carriage_return
    cmp cl, 0xa
    jz .is_line_feed

    cmp cl, 0x8				  ;BS(backspace)的asc码是8
    jz .is_backspace
    jmp .put_other	   

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;判断是否为退格
.is_backspace:
    dec bx
    shl bx,1
    mov byte [gs:bx], 0x20		  ;将待删除的字节补为0或空格皆可
    inc bx
    mov byte [gs:bx], 0x07
    shr bx,1
    jmp .set_cursor

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;是ascii码
.put_other:
    shl bx, 1				     ; 光标位置是用2字节表示,将光标值乘2,表示对应显存中的偏移字节
    mov [gs:bx], cl			     ; ascii字符本身
    inc bx
    mov byte [gs:bx],0x07        ; 字符属性
    shr bx, 1				     ; 恢复老的光标值
    inc bx				         ; 下一个光标值
    cmp bx, 2000		   
    jl .set_cursor			     ; 若光标值小于2000,表示未写到显存的最后,则去设置新的光标值
					             ; 若超出屏幕字符数大小(2000)则换行处理
.is_line_feed:				     ; 是换行符LF(\n)
.is_carriage_return:		     ; 是回车符CR(\r)
    xor dx, dx				     ; dx是被除数的高16位,清0.
    mov ax, bx				     ; ax是被除数的低16位.
    mov si, 80				     ; 由于是效仿linux，linux中\n便表示下一行的行首，所以本系统中，
    div si				         ; 把\n和\r都处理为linux中\n的意思，也就是下一行的行首。
    sub bx, dx				     ; 光标值减去除80的余数便是取整

.is_carriage_return_end:		 ; 回车符CR处理结束
    add bx, 80
    cmp bx, 2000
.is_line_feed_end:			     ; 若是LF(\n),将光标移+80便可。  
    jl .set_cursor

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;滚动屏幕
.roll_screen:				     ; 若超出屏幕大小，开始滚屏
    cld  
    mov ecx, 960				 ; 一共有2000-80=1920个字符要搬运,共1920*2=3840字节.一次搬4字节,共3840/4=960次 
    mov esi, 0xb80a0			 ; 第1行行首
    mov edi, 0xb8000			 ; 第0行行首
    rep movsd				  
    mov ebx, 3840			     ; 最后一行填充为空白
    mov ecx, 80				     ; 一行是80字符(160字节),每次清空1字符(2字节),一行需要移动80次
.cls:
    mov word [gs:ebx], 0x0720    ;0x0720是黑底白字的空格键
    add ebx, 2
    loop .cls 
    mov bx,1920				     ;将光标值重置为1920,最后一行的首字符.

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;设置光标值为bx
.set_cursor:   
    mov dx, 0x03d4			     ;索引寄存器
    mov al, 0x0e			     ;用于提供光标位置的高8位
    out dx, al
    mov dx, 0x03d5			     ;通过读写数据端口0x3d5来获得或设置光标位置 
    mov al, bh
    out dx, al

    mov dx, 0x03d4
    mov al, 0x0f
    out dx, al
    mov dx, 0x03d5 
    mov al, bl
    out dx, al
    .put_char_done: 
    popad
    ret
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110

这个函数还是用汇编写的，因为涉及到操作一些端口。

四、打印字符串

由于我们已经实现了打印一个字符的方法，所以这里我们使用C编程来实现打印字符串，与打印数字

void put_str(uint8_t* _str) {
    while(*_str) {
        put_char(*_str);
        _str++;
    }
    return NULL;
}
1
2
3
4
5
6
7

调用我们在汇编中写的接口

五、打印数字

/* 把一个32位无符号数写到控制台光标处，十进制 */
void put_int(uint32_t num) {
    char int_digits[] = "0123456789";
    char int_string[20];  // 无符号整数转换为十六进制最多占据8位字符，再加上字符串结束符'\0'
    int i = 0;

    if (num == 0) {
        int_string[0] = '0';
        int_string[1] = '\0';
    } else {
        while (num != 0) {
            int_string[i] = int_digits[num % 10];
            num /= 10;
            i++;
        }
        int_string[i] = '\0';

        // 反转字符串
        int start = 0, end = i - 1;
        while (start < end) {
            char temp = int_string[start];
            int_string[start] = int_string[end];
            int_string[end] = temp;
            start++;
            end--;
        }
    }
    put_str(int_string);
}

/* 把一个32位无符号数写到控制台光标处，十六进制 */
void put_hex(uint32_t num) {
    char hex_digits[] = "0123456789ABCDEF";
    char hex_string[9];  // 无符号整数转换为十六进制最多占据8位字符，再加上字符串结束符'\0'
    int i = 0;

    if (num == 0) {
        hex_string[0] = '0';
        hex_string[1] = '\0';
    } else {
        while (num != 0) {
            hex_string[i] = hex_digits[num % 16];
            num /= 16;
            i++;
        }
        hex_string[i] = '\0';

        // 反转字符串
        int start = 0, end = i - 1;
        while (start < end) {
            char temp = hex_string[start];
            hex_string[start] = hex_string[end];
            hex_string[end] = temp;
            start++;
            end--;
        }
    }
    put_char('0');
    put_char('x');
    put_str(hex_string);
}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

写了两个接口，一个用来打印十进制，一个用来打印十六进制。

六、使用makefile

之前一直是几个程序，因为现在程序变多了，我们也使用一下makefile，提升编译效率

AS = nasm
CC = gcc
LD = ld
ACFLAG = -Wall -m32 -c -fno-builtin -fno-stack-protector -W -Wstrict-prototypes -Wmissing-prototypes 
ASFLAG = -I src/boot/
LDFLAG = -m elf_i386 -e main -Ttext 0xc0001500 -T os.lds

###################################################################################### 头文件
INCUDIRS  := src/lib \
			 src/lib/kernel
INCLUDE   := $(patsubst %, -I %, $(INCUDIRS))

###################################################################################### C文件与S文件的编译
SRCDIRS   := src/kernel \
			 src/lib \
			 src/lib/kernel

SFILES    := $(foreach dir, $(SRCDIRS), $(wildcard $(dir)/*.s))
CFILES    := $(foreach dir, $(SRCDIRS), $(wildcard $(dir)/*.c))
SFILENDIR := $(notdir $(SFILES))
CFILENDIR := $(notdir $(CFILES))
SOBJS     := $(patsubst %.s, build/%.o, $(SFILENDIR))
COBJS     := $(patsubst %.c, build/%.o, $(CFILENDIR))
OBJS 	  := $(COBJS) $(SOBJS) 

VPATH     := $(SRCDIRS)

$(SOBJS):build/%.o:%.s
	$(AS) -f elf $(ASFLAG) $(INCLUDE) $< -o $@
$(COBJS):build/%.o:%.c
	$(CC) $(ACFLAG) $(INCLUDE) $< -o $@

###################################################################################### 单独编译代码启动
bin/mbr.bin: src/boot/mbr.s
	$(AS) $(ASFLAG) $< -o $@
bin/loader.bin: src/boot/loader.s
	$(AS) $(ASFLAG) $< -o $@

###################################################################################### 链接代码 # $(LD) $^ $(LDFLAGS) -o $@
bin/kernel.bin:$(OBJS)
	$(LD) $(LDFLAG) $^ -o $@
	

.PHONY: mk_dir clear copy
# 查看编译缓存的文件是否存在，存在就继续，不存在则创建
mk_dir:
	if [ ! -d build ];then mkdir build;fi
	if [ ! -d bin ];then mkdir bin;fi
# 删除编译缓存的文件
clear:
	rm -rf ./build/*
	rm -rf ./bin/*
# 复制二进制程序
copy:
	dd if=bin/mbr.bin of=/home/lyj/bochs/bin/hd60M.img bs=512 count=1 seek=0 conv=notrunc
	dd if=bin/loader.bin of=/home/lyj/bochs/bin/hd60M.img bs=512 count=8 seek=1 conv=notrunc
	dd if=bin/kernel.bin of=/home/lyj/bochs/bin/hd60M.img bs=512 count=200 seek=10 conv=notrunc
# 启动仿真
begin:
	/home/lyj/bochs/bin/bochs -f /home/lyj/bochs/bin/bochsrc.disk 
# 编译程序
build: bin/mbr.bin bin/loader.bin bin/kernel.bin
# 启动所有程序
all: mk_dir clear build copy begin

print:
	@echo $(SOBJS)
	@echo $(COBJS)
	@echo $(OBJS)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

七、仿真

看一下仿真结果

结束语

我们今天可以在终端上输出字符了，其中有四个接口函数。显示字符还是比较简单的，只是往相应的内存位置填充字符即可。

/* 把一个字符写到控制台光标处 */
void put_char(uint8_t char_asci);
/* 把一个字符串写到控制台光标处 */
void put_str(uint8_t* _str);
/* 把一个32位无符号数写到控制台光标处，十进制 */
void put_int(uint32_t num);
/* 把一个32位无符号数写到控制台光标处，十六进制 */
void put_hex(uint32_t num);
1
2
3
4
5
6
7
8