以汇川中型PLC（AM系列）为例，CODESYS平台变量与字节数组互转的多种方法

我们做通讯时，常常要将变量转成字节数组，拷贝进入发送缓冲区（也是字节数组），再进行发送。接收端的变量切分必须准确，然后再正确地转换成对应类型的变量，否则，收到后也无法正确解析。

由于存在字节对齐的规则，我们查看结构变量的字节大小时，常常发现比所有变量的字节之和要大。这也意味着，如果我们用指针直接访问结构变量时，其成员的位置并不一定是按照成员变量的字节顺序排列，因此，我们需要进行一些确切性的变换来让这些字节按照成员的顺序和大小进行排列。

本文以汇川AM系列PLC的编程软件InoProShop为例（它是CODESYS平台，支持大部分的CODESYS功能和语法），阐述CODESYS里3种获取结构变量里数组的方法（也可以用于反向转换）。

此处我们定义了一个结构：

TYPE DUT_SEND_DATA_Normal :
STRUCT
    STAMP :UDINT;//单位为微秒的时间戳 起始地址：0
    data1:UINT;//UInt类型的数值
    data2:REAL;//浮点数类型的数值
    data3:LREAL;;//双精度类型的数值
END_STRUCT
END_TYPE

一、利用M区域进行访问

M区域有字节编号，可以直接使用。该方法较复杂，但是，适用于V2和V3版本。

在全局变量里定义一个该结构的变量，下载运行，就可以在线看到每个变量的起始地址，然后就可以在程序里将这些字节逐个移入发送缓冲区：

二、利用指针进行操作

每个变量都有内存起始地址，通过指针进行获取，然后进行指针操作，也可以获取变量的字节数组。该方法适用于V2和V3版本，并且可以不需要借助M区域。

1、在主程序里新建局部变量：

clockus:ULINT;
sendPulse:BOOL;
sendDataNormal:DUT_SEND_DATA_Normal;
pSource:POINTER TO BYTE;
pTarget:POINTER TO BYTE;
id_SendBuffer:ARRAY[0..199] OF BYTE;//发送缓冲器。

2、在主程序里增加以下语句：

GetSystemTime(uliTimeUs=>clockus);//获取系统时间（微秒为单位）
sendDataNormal.STAMP:=ULINT_TO_UDINT(clockus);//截取低4字节的值。
sendPulse:=NOT(sendPulse);//发送脉冲
 
//周期计数
IF sendPulse THEN
    sendDataNormal.data1:=sendDataNormal.data1+1;
    IF UINT_TO_INT( sendDataNormal.data1) >=30000 THEN
        sendDataNormal.data1:=0;
    END_IF
END_IF
 
//双精度格式的周期计数
sendDataNormal.data3:=UINT_TO_LREAL(sendDataNormal.data1);
 
//数据打包到发送缓冲器，直接操作字节数组。
pTarget:=ADR(id_SendBuffer);
 
pSource:=ADR(sendDataNormal.STAMP);
FOR i:=0 TO SIZEOF(sendDataNormal.STAMP)-1 BY 1 DO
    pTarget^:=pSource^;
    pTarget:=pTarget+1;
    pSource:=psource+1;
END_FOR
 
pSource:=ADR(sendDataNormal.data1);
FOR i:=0 TO SIZEOF(sendDataNormal.data1)-1 BY 1 DO
    pTarget^:=pSource^;
    pTarget:=pTarget+1;
    pSource:=psource+1;
END_FOR
 
pSource:=ADR(sendDataNormal.data2);
FOR i:=0 TO SIZEOF(sendDataNormal.data2)-1 BY 1 DO
    pTarget^:=pSource^;
    pTarget:=pTarget+1;
    pSource:=psource+1;
END_FOR
 
pSource:=ADR(sendDataNormal.data3);
FOR i:=0 TO SIZEOF(sendDataNormal.data3)-1 BY 1 DO
    pTarget^:=pSource^;
    pTarget:=pTarget+1;
    pSource:=psource+1;
END_FOR

三、利用联合类型（Union）进行操作

联合类型是一种新的数据结构，可以定义同一起始地址的不同变量类型（包括字节数组），操作方法如下：

1、定义几种变量类型的数据结构：

TYPE union_udint :
UNION
    Value:UDINT;
    Bytes:ARRAY[0..3] OF BYTE;
END_UNION
END_TYPE
 
TYPE union_uint :
UNION
    Value:UINT;
    Bytes:ARRAY[0..1] OF BYTE;
END_UNION
END_TYPE
 
TYPE union_real :
UNION
    Value:REAL;
    Bytes:ARRAY[0..3] OF BYTE;
END_UNION
END_TYPE
 
TYPE union_lreal :
UNION
    Value:LREAL;
    Bytes:ARRAY[0..7] OF BYTE;
END_UNION
END_TYPE

2、定义新的数据结构

TYPE DUT_SEND_DATA:
STRUCT
    STAMP :union_udint;//单位为微秒的时间戳 起始地址：0
    data1:union_uint;//UInt类型的数值
    data2:union_real;//浮点数类型的数值
    data3:union_lreal;//双精度类型的数值
END_STRUCT
END_TYPE

3、在主程序里新建局部变量：

clockus:ULINT;
sendPulse:BOOL;
sendData:DUT_SEND_DATA;
id_SendBuffer:ARRAY[0..199] OF BYTE;//发送缓冲器。
pArray:UINT;
i:UINT;

4、在主程序里增加以下语句：

GetSystemTime(uliTimeUs=>clockus);//获取系统时间（微秒为单位）
sendPulse:=NOT(sendPulse);//发送脉冲
sendData.STAMP.Value:=ULINT_TO_UDINT(clockus);//截取低4字节的值。
 
//周期计数
IF sendPulse THEN
    sendData.data1.Value:=sendData.data1.Value+1;
    IF UINT_TO_INT( sendData.data1.Value) >=30000 THEN
        sendData.data1.Value:=0;
    END_IF
    sendData.data3.Value:=UINT_TO_LREAL(sendData.data1.Value);
END_IF
 
//数据打包到发送缓冲器，直接操作字节数组。
pArray:=0;
FOR i:=0 TO SIZEOF(sendData.STAMP.Bytes)-1 BY 1 DO
    id_SendBuffer[pArray]:=sendData.STAMP.Bytes[i];
    pArray:=pArray+1;
END_FOR
 
FOR i:=0 TO SIZEOF(sendData.data1.Bytes)-1 BY 1 DO
    id_SendBuffer[pArray]:=sendData.data1.Bytes[i];
    pArray:=pArray+1;
END_FOR
 
FOR i:=0 TO SIZEOF(sendData.data2.Bytes)-1 BY 1 DO
    id_SendBuffer[pArray]:=sendData.data2.Bytes[i];
    pArray:=pArray+1;
END_FOR
 
FOR i:=0 TO SIZEOF(sendData.data3.Bytes)-1 BY 1 DO
    id_SendBuffer[pArray]:=sendData.data3.Bytes[i];
    pArray:=pArray+1;
END_FOR

四、小结

通过联合类型可以安全、直观地进行变量与字节数组的互相转换，虽然其本质也是指针，但是，这种方式不易犯错误，因此，值得大家掌握。

2023年10月5日