深入浅出DAX：数据分析

深入浅出DAX：数据分析

01、区间分析

1. 数据区间分析

在Power BI中，选择“主页”→“输入数据”，创建“区间辅助表”，如图1所示。

■ 图1 区间辅助表

创建度量值M.区间次数，表达式如下：

M.区间次数 =
VAR A =
    SELECTEDVALUE ( '区间辅助表'[起始值] )
VAR B =
    SELECTEDVALUE ( '区间辅助表'[结束值] )
VAR C =
    CALCULATE (
        COUNT ( DK[包装方式] ),
        FILTER ( DK, DK[入库] > A && DK[入库] <= B )
    )
RETURN
    C

在可视化区域选择“表”，将区间辅助表的区间、起始值、结束值及度量值M.区间次数拖入“值”区域。相关设置及返回的值如图2所示。

■ 图2  统计入库量在各所属区间内出现的次数

2. 频次分析

采用DATATABLE()函数，创建频次表，表达式如下：

频次表 = DATATABLE (
    "频次", STRING,
    "最小值", INTEGER,
    "最大值", INTEGER,
    {
    { "1-2次", 1, 2 },
    { "3-4次", 3, 4 },
    { "5-6次", 5, 6 }
    }
)

返回的值如图3所示。

■ 图3 频次表

在Power BI中，选择“主页”→“Excel工作簿”，打开“D:\深入浅出DAX\2数据源\DEMO.xlsx”，在导航器中选择订单及日期表，单击“加载”按钮。创建度量值M.订单次数，表达式如下：

M.订单次数 =
-- VAR A = MAX ( '日期'[日期] )
VAR B = SELECTEDVALUE ( '频次表'[最小值] )
VAR C = SELECTEDVALUE ( '频次表'[最大值] )
VAR D =
    SUMMARIZE (
        '订单',
        '订单'[订单来源],
        "订单数量",
    CALCULATE (
                COUNT ( '订单'[订单来源] )
                -- , FILTER ( ALL ( '日期' ), '日期'[日期] <= A )
        )
    )
VAR E =
    CALCULATE (
        COUNTROWS (
            FILTER ( D, [订单数量] >= B && [订单数量] <= C )
        )
    )
RETURN
    E

在可视化区域选择“表”，将频次表中的频次及度量值M.订单次数拖入“值”区域。返回的值如图4所示。

■ 图4 订单次数统计

如需加入'日期'[日期]为切片器，只需将度量值M.订单次数中的注释符号(表达式中语句前面的--)取消。

02、ABC分析

ABC分析起源于80/20分析，在质量管理、库存管理等方面应用较为广泛。ABC分析是一种分类管理技术，将对象划分为重要的A类、一般的B类及不重要的C类。

1. 动态ABC分析（一）

新建静态ABC表，表达式如下：

静态ABC =
SUMMARIZECOLUMNS (
    '运单'[产品],
    '运单'[包装方式],
    "数量和", SUM ( '运单'[数量] )
)

在静态ABC表中，新建计算列累计值、累计百分比、ABC分类，表达式如下：

累计值 =
VAR A = '静态ABC'[数量和]
RETURN
    CALCULATE (
       SUM ( [数量和] ),
        FILTER (
          '静态ABC',
            '静态ABC'[数量和] >= A
        )
    )
 
累计百分比 = DIVIDE([累计值],SUM([数量和]))
 
ABC分类 =
SWITCH (
    TRUE (),
    [累计百分比] <= 0.7, "A",
    [累计百分比] <= 0.9, "B",
    "C"
)

返回的值如图5所示。

■ 图5 在表中新增3列

创建度量值M.数量和、M.ABC识别，表达式如下：

M.数量和 = SUM('静态ABC'[数量和])
 
M.ABC识别 =
SWITCH (
   TRUE (),
    SELECTEDVALUE ( '静态ABC'[ABC分类] ) = "A", "GREEN",
    SELECTEDVALUE ( '静态ABC'[ABC分类] ) = "B", "YELLOW",
    "RED"
)

在可视化区域，选择“折线和簇状柱形图”，相关设置如图6所示。

■ 图6 添加与设置视觉对象（1）

返回的值如图7所示。

■ 图7 添加与设置视觉对象（2）

2. 动态ABC分析（二）

在运单表中创建计算列列.年，表达式如下：

运.年 = YEAR('运单'[发车时间])

在静态ABC表中，增加'运单'[运.年]。表达式如下：

静态ABC =
SUMMARIZECOLUMNS (
    '运单'[运.年], //新增的列，方便后续的多维度动态分析
    '运单'[产品],
    '运单'[包装方式],
    "数量和", SUM ( '运单'[数量] )
)

创建度量值M.累计百分比，表达式如下：

M.累计百分比 =
VAR A = [M.数量和]
VAR B =
    CALCULATE (
        [M.数量和],
        FILTER ( ALL ( '静态ABC'[产品] ), [M.数量和] >= A )
    )
RETURN
    DIVIDE (
        B,
        CALCULATE ( [M.数量和], ALL ( '静态ABC'[产品] ) )
    )

将图8的“折线和簇状柱形图”中的“行值”更换为度量值M.累计百分比。在可视化区域新增两个切片器，“字段”分别为静态ABC表中的运.年、包装方式。相关设置及返回值如图9所示。

■ 图9 添加与设置视觉对象（3）

选择切片器，返回的值如图10所示。

■ 图10 添加与设置视觉对象（4）

03、RFM分析

RFM模型是衡量客户价值和客户创造利益能力的重要工具和手段，RFM是最近一次消费时间间隔（Recency），消费频率（Frequency）、消费金额（Monetary）三个指标首字母组合，其中，R值具备望小特性，F值和M值为具备望大特性，即R值越小越好而F值和M值则是越大越好。

1. 模型设计

在管理过程中，对R、F、M这三个因子进行高低二水平的全因子组合设计，则2k全因子组合设计后可形成8种（23=8）组合方案。若对其中的低水平用1表示、高水平用2表示，则组合设计后的RFM客户价值分析模型见表1。

■ 表1 RFM价值分析模型

R值的高、低水平的判定逻辑与计算顺序：

（1）用事实表中的最大日期与该客户的最近活跃日期相比较，获取日期的间隔天数。

（2）将所有客户的日期间隔天数进行求平均，得到事实表中R值的整体平均值。

（3）以整体均值为依据，对各客户的间隔天数进行1（低水平）2（高水平）代码化。

采用类似的方法对F值及M值代码化，然后将代码化的R值、F值、M值进行组合，最终形成类似222、212这样的RFM组合码，由此得到该客户的价值分类，其中，M代码为2的为重要客户，否则为一般客户。RF组合码为22的属价值客户，RF组合码为11的属已流失客户。RF组合码为21的需深耕以提高其消费频率的客户；RF组合码为12的属近期无交易需唤回以继续消费的客户。

2. 数据准备

在Power BI中,通过“主页”→“Excel工作簿”，将DEMO.xlsx中的订单、运单、RFM表进行加载并在订单表与运单表中创建关联，主键是订单表的运单编号，外键是运单表的运单编号。由于模型中无客户字段，现暂以订单表中的“订单来源”字段比拟客户进行RFM分析。相关数据模型与表格如图10-35所示。

■ 图11 RFM数据模型

3. 计算R值

计算各客户最近活跃日的间隔天数，表达式如下：

M.R1间隔天数 =
DATEDIFF (
    MAX ( '运单'[发车时间] ),
    MAXX (
        ALL ( '运单'[发车时间] ),
        '运单'[发车时间]
    ),
    DAY
)

计算R值的整体平均值，表达式如下：

M.R2整体平均天数 =
AVERAGEX (
    ALLSELECTED ( '订单'[订单来源] ),
    [M.R1间隔天数]
)

对R值的高低水平代码化，表达式如下：

M.R3R值代码化 =
IFERROR(
    IF ([M.R1间隔天数] < [M.R2整体平均天数],2,1),
BLANK()
)

4. 计算F值

计算各客户最近活跃的频率数，表达式如下：

M.F1频数 = DISTINCTCOUNT('运单'[订单编号])

计算F值的整体平均值，表达式如下：

M.F2整体平均频数 =
AVERAGEX (
    ALLSELECTED ( '订单'[订单来源] ),
    [M.F1频数]
)

对F值的高低水平代码化，表达式如下：

M.F3F值代码化 =
IFERROR(
    IF ( [M.F1频数] > [M.R2整体平均天数],2,1),
    BLANK ()
)

5. 计算M值

计算各客户最近活跃的数量额，表达式如下：

M.M1活跃额 = SUM('运单'[数量])

计算M值的整体平均值，表达式如下：

M.M2整体均额 =
AVERAGEX (
    ALLSELECTED ( '订单'[订单来源] ),
    [M.M1活跃额]
)

对M值的高低水平代码化，表达式如下：

M.M3M值代码化 =
IFERROR(
    IF ( [M.M1活跃额] > [M.M2整体均额],2,1),
    BLANK ()
)

6. RFM客户价值归类

对客户的RFM价值进行归类。

M.RFM价值归类 =
VAR A = [M.R3R值代码化] & [M.F3F值代码化] & [M.M3M值代码化]
RETURN
    CALCULATE ( VALUES ( 'RFM表'[客户价值] ), 'RFM表'[RFM] = A )

7. RFM客户价值分析

创建表，对客户进价价值分析。

RFM客户价值分析表 =
ADDCOLUMNS (
    SUMMARIZE ( '订单', '订单'[订单来源] ),
    "R天", [M.R1间隔天数],
    "F数", [M.F1频数],
    "M量", [M.M1活跃额],
    "RFM值",
        [M.R3R值代码化] & [M.F3F值代码化] & [M.M3M值代码化],
    "客户类型", [M.RFM价值归类]
)

返回的值如图12所示。

■ 图12 RFM客户价值分析

8. 可视化分析

创建度量值M.RFM订单来源，表达式如下：

M.RFM订单来源 =
IF (
    HASONEVALUE ( 'RFM客户价值分析表'[客户类型] ),
    CONCATENATEX (
        VALUES ( 'RFM客户价值分析表'[订单来源] ),
        'RFM客户价值分析表'[订单来源],
        "、"
    )
)

在Power BI可视化区域，单击矩阵图。将RFM客户价值分析表中的客户类型拖入“行”区域，勾选度量值M.RFM订单来源。相关设置及返回的值如图13所示。

■ 图13 视觉对象设置及返回的值