• 8086 汇编小程序

    仅以此文记录我在Centos上使用DosBox写8086汇编小程序，不知为何DosBox总是会将我当前用户Logout，然后我必须重新登录的艰苦岁月……

    1：HelloWorld

    1. DATA SEGMENT
    2. str db 'Hello World$'    ；要输出的字符串必须要以$结尾
    3. DATA ENDS
    4.  
    5. CODE SEGMENT
    6. ASSUME CS:CODE,DS:DATA    ；将CS和CODE，DS和DATA段建立联系
    7. START: 
    8.        MOV BX,DATA 
    9.        MOV DS,BX
    10.        LEA DX,str 
    11.        MOV AH,9
    12.        INT 21H
    13.  
    14.        MOV AH,4CH        ；将控制权返回给终端。
    15.        INT 21H
    16. CODE ENDS
    17. END START

    备注：
    1：
    MOV BX,DATA
    MOV DS,BX
    将数据段的值给DS寄存器，但是不能直接 MOV DS,DATA，因为mov操作中不允许将立即数给DS。
    2：LEA指令：将源操作数的地址移入目的操作数。
    LEA BX,Buffer
    源操作数：必须是一个存储器操作数
    目的操作数：16位通用寄存器
    3：mov AH,9 ；使用9号系统调用从DX中读取字符串输出
    int 21H; 产生系统中断。

    2：从键盘输入两个一位十进制数，计算两个数之和，并将结果在屏幕上显示出来。

    1. DATA SEGMENT
    2.     INFOR1 DB 'Please Input the First Data(<10):$'
    3.     INFOR2 DB 0AH,0DH,'Please Input the Second Data(<10):$' ; 0A 是 '\n' 0D 是 '\r'，回车换行
    4.     INFOR3 DB 0AH,0DH,'The Result is:$'
    5. DATA ENDS
    6.  
    7. CODE SEGMENT
    8.     ASSUME CS:CODE,DS:DATA
    9. START:
    10.     MOV AX,DATA
    11.     MOV DS,AX
    12.     LEA DX,INFOR1      ;输出第一条提示语句
    13.     MOV AH,09H
    14.     INT 21H
    15.  
    16.     MOV AH,01H        ;1号系统调用将字符输入至AL中。
    17.     INT 21H
    18.     SUB AL,30H        ;输入的位ASCII码，所以减去48
    19.     MOV BL,AL
    20.  
    21.     LEA DX,INFOR2
    22.     MOV AH,09H
    23.     INT 21H
    24.  
    25.     MOV AH,01H
    26.     INT 21H
    27.     SUB AL,30H
    28.  
    29.     XOR AH,AH       ;将AH清空
    30.     ADD AL,BL       
    31.     AAA             ;加法ASCII码调整指令
    32.  
    33.     PUSH AX
    34.     LEA DX,INFOR3
    35.     MOV AH,09H
    36.     INT 21H
    37.  
    38.     POP AX
    39.     PUSH AX
    40.     MOV DL,AH
    41.     ADD DL,30H     ;计算结束之后加上48输出。
    42.     MOV AH,02H     ;2号系统调用，输出单个字符,在汇编中想输出数字只能单个ASCII码的输出。
    43.     INT 21H
    44.     POP AX
    45.     MOV DL,AL
    46.     ADD DL,30H  
    47.     MOV AH,02H
    48.     INT 21H
    49.  
    50.     MOV AH,4CH
    51.     INT 21H
    52. CODE ENDS
    53. END START

    备注：
    1： AAA指令：加法ASCII码调整指令。

    MOV AX,0007H ;AL=07H AH=00H MOV BL,08H ;BL=08H ADD AL,BL ;AL=0FH AAA ;AL=05H AH=01H

    3：编写一段程序比较两个字符串是否相同，相同输出MATCH!，不相同输出NO MATCH!。

    思路：

    1. 先计算两个串长度，如果不同直接退出，相同执行第2步
    2. 挨个比较字符是否相同，若有不相同结束，直到比较结束全部相同
    3. 输出match
    1. DATA  SEGMENT
    2.     STR1 DB 'ABCDEFG$'              
    3.     N EQU $-STR1               ；给N赋值，$表示当前指令的地址，$-STR1表示当前位置到STR1头部的距离，也就是STR1的长度。
    4.     STR2 DB 'BCDEFG$'  
    5.     M EQU $-STR2                   
    6.     MESS DB 'NO MATCH!$'
    7.     RIGHT DB 'MATCH!$'
    8. DATA  ENDS
    9. CODE SEGMENT
    10. ASSUME CS:CODE,DS:DATA,ES:DATA
    11.  
    12. BEGIN:
    13.     MOV AX,DATA
    14.     MOV DS,AX                
    15.     MOV AX,DATA
    16.     MOV ES,AX                
    17.     MOV AL,N                   
    18.     CMP AL,M          ；比较长度是否相等,相等ZF=0，否则ZF=1
    19.     JNZ EXIT           ;JNZ：jump if not zero ,zero 指的是比较结果，而不是ZF标志位的值
    20.     LEA SI,STR1              
    21.     LEA DI,STR2
    22.     MOV CL,N
    23.     MOV CH,0
    24.     CLD               
    25.     REPE CMPSB        ；挨个比较单个字符，如果有一个不等就跳EXIT
    26.     JNZ EXIT                                                                
    27.     LEA DX,RIGHT              
    28.     JMP OUT1
    29.  
    30. EXIT:   
    31.     LEA DX,MESS
    32. OUT1:      
    33.     MOV AH,9                   
    34.     INT 21H
    35.     MOV AH,4CH                
    36.     INT 21H
    37.  
    38. CODE  ENDS
    39. END BEGIN

    备注：
    1：CMP指令：
    不影响两个操作数的原大小，影响的是状态标志位，如果相等，ZF=1。否则ZF=0

    2：JNZ指令的逻辑写出来就是下面这样

    JNZ(ZF == 0) { //如果ZF == 0 ,则跳转 } //如果ZF == 1,则不跳转

    4：汇编读写文件

    输入原文件名->将文件读入预先定义好的缓冲区->输入新的文件名->将缓冲区的内容写入新文件。

    （这部分代码是马辉完成的，我们共同做的汇编程序大赛http://blog.csdn.net/yangbodong22011/article/details/53716225，他负责文件读写部分，我负责加密解密算法部分）

    1. data segment
    2.  
    3. filePath db 20,?,20 dup(?);存储原文件名称
    4. newFilePath db 10,?,10 dup(?),00 ;存储加密或者解密的文件的路径
    5. fileHandle db 2 dup(?);存储文件代号
    6. fileBuffer db 10000  dup(?);文件缓冲区
    7. fileInputTip db 'please input source file path:$';提示源文件路径
    8. newFileInputTip db 'please input new file path:$';提示新文件路径
    9. openErrorTip db 'open file error !!$';提示打开文件失败
    10. readErrorTip db 'read file error !!$' ;提示读文件失败
    11. fileCount db ? ;定义实际读取的字节数
    12.  
    13. data ends
    14.  
    15. code segment
    16. assume cs:code,ds:data
    17.  
    18. start:
    19.  mov ax,data
    20.  mov ds,ax
    21.  
    22.  call openFile ;打开文件
    23.  call readFile ;将文件读至缓冲区
    24.  call closeFile ;关闭文件
    25.  
    26.  call createFile ;创建新文件
    27.  call writeFile ;写文件
    28.  call closeFile ;关闭文件
    29.  
    30.  call returnDos ;返回DOS
    31.  
    32.  
    33.  
    34.  
    35. ;***************
    36. ;打开文件
    37. openFile proc near
    38.  ;9号功能调用，提示输入文件名
    39.  mov dx,offset fileInputTip
    40.  mov ah,9
    41.  int 21h
    42.  ;10号功能调用，将文件名存储在filePath中
    43.  mov dx,offset filePath
    44.  mov ah,10
    45.  int 21h
    46.  ;换行处理
    47.  call nextLine
    48.  ;取得键盘上输入的实际的个数
    49.  lea bx,filePath+1
    50.  ; 清空cx
    51.  xor cx,cx
    52.  ;将键盘上实际输入的个数送给cx
    53.  mov cl,[bx]
    54.  ;取得文件实际的存储路径
    55.  lea bx,filePath+2
    56.  ;处理enter的ascall码
    57.  call findEnter
    58.  ;系统调用，打开文件
    59.  mov ah,3dh
    60.  mov al,00
    61.  lea dx,filePath+2
    62.  int 21h
    63.  ; 若CF为1，打开失败
    64.  jc openError
    65.  ;若CF为0，打开成功，获取返回的ax中的文件代号
    66.  jmp getFileHandle
    67. getFileHandle:
    68.  ;取得fileHandle的地址空间
    69.  lea bx,fileHandle
    70.  ;将文件代号保存在fileHandle中
    71.  mov [bx],ax
    72.  ret
    73. openError:
    74.  ;9号功能调用，提示打开文件失败
    75.  mov dx,offset openErrorTip
    76.  mov ah,9
    77.  int 21h
    78.  ;返回dos
    79.  call returnDos
    80.  ret
    81. openFile endp
    82. ;***************
    83.  
    84.  
    85. ;***************
    86. ;读文件
    87. readFile proc near
    88.  ;系统调用，读文件
    89.  mov ah,3fh
    90.  lea si,fileHandle
    91.  mov bx,[si]
    92.  mov cx,10000
    93.  lea dx,fileBuffer
    94.  int 21h
    95.  ;cf＝1，读文件失败，cf＝0，读文件成功
    96.  ;提示读取文件失败
    97.  jc readError
    98.  jmp getFileCount
    99. getFileCount:
    100.  ;将实际读取的字节数放在fileCount中
    101.  lea bx,fileCount
    102.  mov [bx],ax
    103.  ret
    104. readError:
    105.  ;9号功能调用，提示读文件失败
    106.  mov dx,offset readErrorTip
    107.  mov ah,9
    108.  int 21h
    109.  ;返回dos
    110.  call returnDos
    111.  ret
    112. readFile endp
    113. ;***************
    114.  
    115.  
    116.  
    117. ;***************
    118. ;换行处理
    119. nextLine proc near
    120.  mov dl,0dh
    121.  mov ah,2
    122.  int 21h
    123.  mov dl,0ah
    124.  mov ah,2
    125.  int 21h
    126.  ret
    127. nextLine endp
    128. ;***************
    129.  
    130.  
    131. ;***************
    132. ;将回车所占的地址空间的值设为00h
    133. findEnter proc near
    134. next1:
    135.  inc bx
    136.  loop next1
    137.  mov al,00h
    138.  mov [bx],al
    139.  ret
    140. findEnter endp
    141. ;***************
    142.  
    143.  
    144. ;***************
    145. ;返回dos
    146. returnDos proc near
    147.  mov ah,4ch
    148.  int 21h
    149.  ret
    150. returnDos endp
    151. ;***************
    152.  
    153. ;***************
    154. ;关闭文件
    155. closeFile proc near
    156.  mov ah,3eh
    157.  int 21h
    158.  ret
    159. closeFile endp
    160. ;***************
    161.  
    162. ;***************
    163. ;创建文件，cf＝0，返回文件代号，保存在ax中；cf＝1,创建失败
    164. createFile proc near
    165. create:
    166.  ;9号功能调用，提示输入新的文件名加路径
    167.  mov dx,offset newFileInputTip
    168.  mov ah,9
    169.  int 21h
    170.  ;10号功能调用，将新文件名艺伎路径保存在newFilePath中
    171.  mov dx,offset newFilePath
    172.  mov ah,10
    173.  int 21h
    174.  ;换行处理
    175.  call nextLine
    176.  ;取得newFilePath缓冲区中实际输入的字符的个数
    177.  lea bx,newFilePath+1
    178.  ;清空cx
    179.  xor cx,cx
    180.  ;将newFilePath缓冲区实际存储的个数送给cx
    181.  mov cl,[bx]
    182.  ;判断是否输入
    183.  cmp cx,00h
    184.  ;如果输入的不为空，则跳转continue
    185.  jnz continue
    186.  ;如果输入的为空，则重新输入
    187.  jmp create
    188. continue:
    189.  ;取得实际的存储路径
    190.  lea bx,newFilePath+2
    191.  ;处理enter的ascall码
    192.  call findEnter
    193.  ;系统调用，创建文件
    194.  mov ah,3ch
    195.  mov cx,00
    196.  lea dx,newFilePath+2
    197.  int 21h
    198.  ; 将文件代号保存在fileHandle中
    199.  lea si,fileHandle
    200.  mov [si],ax
    201.  ret
    202. createFile endp
    203. ;***************
    204.  
    205.  
    206. ;***************
    207. ;向文件写数据
    208. writeFile proc near
    209.  ;系统调用，写文件
    210.  mov ah,40h
    211.  lea si,fileHandle
    212.  mov bx,[si]
    213.  lea di,fileCount
    214.  mov cx,[di]
    215.  lea dx,fileBuffer
    216.  int 21h
    217.  ret
    218. writeFile endp
    219. ;***************
    220.  
    221. code ends
    222. end start

    5：汇编生成随机数

    8086 定时器模式生成随机数

    1. ;***************
    2. ;获取随机数 范围1-8
    3. getRand:
    4.     xor al,al
    5.     mov ax, 0h; 间隔定时器
    6.     out 43h,al; 将0送到43h端口
    7.     in al, 40h; 将40h端口的数据送至al
    8.  
    9.     mov bl, 8   ;除8 得到范围为0-7
    10.     div bl 
    11.  
    12.     mov al, ah
    13.     mov ah, 0
    14.  
    15.     inc al     ; 加1 得到范围为1-8
    16.  
    17.     ret
    18.  
    19. ;***************

    6：汇编生成1-N共N位不重复随机数

    例如生成1-8不重复的序列，比如 12435786或者43256718，结合上面生成随机数的程序完成如下。

    1. ;***************
    2. ;创建随机数并存入文件
    3. createRandNum:
    4.       lea si,randNum1      ;randNum1是保存随机数串的字符串
    5.       mov cx,8             ;设定需要产生的个数
    6.       doRand:
    7.         push cx
    8.         createRandNumdo1:           ;循环产生
    9.             call getRand   ;获得一个随机数
    10.  
    11.             xor di,di
    12.             xor cx,cx
    13.  
    14.             lea di,randNum1
    15.             mov cx,8
    16.             createRandNumdo2:  ;将新产生的数字和已经保存的比对
    17.                 mov bh,[di]
    18.                 cmp bh,al 
    19.                 jz createRandNumdo1   ;如果出现重复就继续产生
    20.                 inc di
    21.                 loop createRandNumdo2
    22.  
    23.         mov bh,RandNum[0]         ;保存目前一共产生的随机数个数
    24.         add bh,1
    25.         mov RandNum[0],bh
    26.  
    27.         cmp bh,9               ;如果为Num+1 就结束
    28.         jz mRet
    29.  
    30.         mov [si],al
    31.         inc si
    32.  
    33.  
    34.         pop cx
    35.     loop doRand
    36.  
    37. ;***************
    38. ;获取随机数 范围1-8
    39. getRand:
    40.     xor al,al
    41.     mov ax, 0h; 间隔定时器
    42.     out 43h,al; 将0送到43h端口
    43.     in al, 40h; 将40h端口的数据送至al
    44.  
    45.     mov bl, 8   ;除8 得到范围为0-7
    46.     div bl 
    47.  
    48.     mov al, ah
    49.     mov ah, 0
    50.  
    51.     inc al     ; 加1 得到范围为1-8
    52.  
    53.     ret
    54.  
    55. ;***************
    56.

    7：将一个db类型的每一位取出来保存进一个8个db大小的字符串。

    例如 A的二进制是01000001我们将它每一位分别保存进一个db，得到0 1 0 0 0 0 0 1 ，将其保存入temp1

    1. fetchBinary:
    2.     xor dx,dx;
    3.  
    4.     lea si,temp1 
    5.     mov dl,[bx]
    6.  
    7.     mov dh,dl; 
    8.     and dh,10000000B    ;先拿出最高位是不是1
    9.     cmp dh,00H          ;如果为0
    10.     jz _1   
    11.     mov dh,01h          ;如果不为0就置为1
    12.     _1:
    13.     mov [si],dh         ;将dh的值也就是0给[si]
    14.     inc si
    15.  
    16.     mov dh,dl  
    17.     and dh,01000000B
    18.     cmp dh,00H
    19.     jz _2
    20.     mov dh,01H
    21.     _2:
    22.     mov [si],dh
    23.     inc si
    24.  
    25.     mov dh,dl  
    26.     and dh,00100000B
    27.     cmp dh,0
    28.     jz _3
    29.     mov dh,01H
    30.     _3:
    31.     mov [si],dh
    32.     inc si
    33.  
    34.     mov dh,dl 
    35.     and dh,00010000B
    36.     cmp dh,00H
    37.     jz _4
    38.     mov dh,01h
    39.     _4:
    40.     mov [si],dh
    41.     inc si
    42.  
    43.     mov dh,dl  
    44.     and dh,00001000B
    45.     cmp dh,00H
    46.     jz _5
    47.     mov dh,01h
    48.     _5:
    49.     mov [si],dh
    50.     inc si
    51.  
    52.     mov dh,dl  
    53.     and dh,00000100B
    54.     cmp dh,00H
    55.     jz _6
    56.     mov dh,01h
    57.     _6:
    58.     mov [si],dh
    59.     inc si
    60.  
    61.     mov dh,dl  
    62.     and dh,00000010B
    63.     cmp dh,00H
    64.     jz _7
    65.     mov dh,01h
    66.     _7:
    67.     mov [si],dh
    68.     inc si
    69.  
    70.     mov dh,dl  
    71.     and dh,00000001B
    72.     cmp dh,00H
    73.     jz _8
    74.     mov dh,01h
    75.     _8:
    76.     mov [si],dh
    77.  
    78.     ret
  • 相关阅读:
    安卓开发面试题
    CPP_D2
    Centos SFTP搭建
    数据结构——二叉树搜索树（二叉搜索树的概念、实现、先序遍历、中序遍历、后序遍历）
    javaScript基础
    基于jacoco和CI做代码覆盖率检测
    JAVA毕业设计潮流奢侈品购物网站计算机源码+lw文档+系统+调试部署+数据库
    vue3+ts+vant移动端H5项目搭建
    C# 第二章『基础语法』◆第2节：switch case语句
    mybatis-plus
  • 原文地址：https://blog.csdn.net/apple_51426592/article/details/127642172