• 电力电子转战数字IC20220629day35——路科实验2b

    目录

    tb3代码改造

    tb3代码

    tb4改造思路：

    tb4结构示意图

     tb4代码

     basic_test

     burst_test

     full_test

     首先复习一下类的知识点

    CSDNhttps://mp.csdn.net/mp_blog/creation/editor/125286941CSDNhttps://mp.csdn.net/mp_blog/creation/editor/125254965

    tb3代码改造

    • 接口和时钟块不变
    • 变量限定为local
    • 端口列表的接口放下来用virtual
    • 初始化用new函数
    • 类里面的变量都是动态变量，不用加automatic了
    • 用到的方法和变量都加上this表示这个当前类的，防止同名问题
    • 用函数将接口给到initiator中
    • 单独的一个类ch_trans来封装发送出去的数据，输送数据的task的输入变成这个类的句柄，而不是原来的标量data，里面的data需要加上句柄索引
    • 队列从存放数据变为存放句柄
    • 生成数据的函数最终返回句柄t
    • 例化initiator时不用再加入接口参数，例化generator不用括号
    • 在initial块中对三个通道的initiator和generator进行初始化和连接到接口上，在三个test中就不用了再做这一步骤了（原本是每个test都需要调用函数来进行初始化）

    tb3代码

    1. `timescale 1ns/1ps
    2. //*********************用类class来改造**************************//
    3.  
    4. //**********************接口和时钟块不变****************************//
    5. interface interface_chen (input clk, input rstn);
    6.  
    7. logic [31:0] channel_data;
    8. logic        channel_valid;
    9. logic        channel_ready;
    10. logic [ 7:0] slave_margin;
    11.  
    12. clocking drv_clk @(posedge clk);
    13. 	default input #1ns output #1ns;
    14. 	input  channel_ready, slave_margin;//采样
    15. 	output channel_data, channel_valid;//驱动
    16. endclocking 
    17.  
    18. endinterface 
    19. //**************************************************//
    20. class ch_trans;
    21. 	int data;
    22. 	int id;
    23. 	int num;
    24. endclass
    25. //**************************************************//
    26. class initiator_chen;
    27. virtual interface_chen intf;//virtual表示在子类中会被调用到，声明类的成员变量接口指针必须用virtual
    28.  
    29. local int idle_cycle;
    30. local string name;
    31.  
    32. function new(string name="initiator_chen");//这里其实就是初始化
    33. 	this.name=name;
    34. 	this.idle_cycle=1;
    35. endfunction
    36.  
    37. //类里面所有变量都是动态变量，不需要加automatic了
    38. function void set_idle_cycle(int n);
    39. 	this.idle_cycle=n;
    40. endfunction
    41.  
    42. function void set_name(string s);
    43. 	this.name=s;
    44. endfunction
    45. //这里替代的是三个接口的例化
    46. function void set_interface(virtual interface_chen intf);
    47. 	if(intf==null)
    48. 		$error("null, need to be intantiated.");
    49. 	else this.intf=intf;
    50. endfunction
    51.  
    52. task chnl_write (input ch_trans t);//数据封装在ch_trans里面，这个类的句柄声明为t
    53. 	@(posedge intf.clk);
    54. 	intf.drv_clk.channel_valid<=1'b1;
    55. 	intf.drv_clk.channel_data<=t.data;//data要加t.引用
    56. 	@(negedge intf.clk);
    57. 	wait(intf.channel_ready==1'b1);
    58. 	$display("%t channel initial [%s] sent data %x", $time, name, t.data);
    59. 	repeat (this.idle_cycle) channel_idle();		
    60. endtask
    61.  
    62. task channel_idle();
    63. 	@(posedge intf.clk);
    64. 	intf.drv_clk.channel_valid<=1'b0;
    65. 	intf.drv_clk.channel_data<=1'b0;
    66. endtask
    67.  
    68.  
    69. endclass 
    70. //**************************************************//
    71. class generator_chen;
    72. ch_trans trans[$];//存放ch_trans句柄的队列
    73. ch_trans t;//声明句柄
    74. int num;
    75. int id;
    76.  
    77. function new(int n);//替代原来的初始化函数，完成初始化
    78. 	this.id=n;
    79. 	this.num=0;
    80. endfunction 
    81.  
    82. //替代生成数据的func get_data
    83. function ch_trans get_trans();//类的句柄函数
    84. 	t=new();//对类进行例化，创建一个名为t的ch_trans对象
    85. 	t.data='h00C0_00000+(this.id<<16)+this.num;
    86. 	t.id=this.id;//把gen的id赋给ch_trans的id
    87. 	t.num=this.num;
    88. 	this.num++;
    89. 	this.trans.push_back(t);
    90. 	return t;
    91. endfunction
    92.  
    93. endclass
    94. //**************************************************//
    95. module tb1_chen();//由于tb对接的是mcdt，所以还是用mcdt定义的那些信号名，输入换成reg，输出换成wire
    96.  
    97. logic          clk;
    98. logic          rstn;
    99. logic [31:0]		mcdt_data_output;
    100. logic				mcdt_valid;
    101. logic [1:0]			mcdt_id;
    102.  
    103. //**************mcdt-接口-generator************************//
    104. interface_chen ch1_intf(.*);//必须用接口名才不会报错，不能用intf
    105. interface_chen ch2_intf(.*);
    106. interface_chen ch3_intf(.*);
    107. //将接口分成3份。分别对应mcdt的信号
    108.  
    109. mcdt_chen dut(//括号里面的信号变成接口里面的
    110.    .clk(clk)
    111.   ,.rstn(rstn)
    112.   
    113.   ,.channel1_data(ch1_intf.channel_data)//信号改为接口中的名称
    114.   ,.channel1_valid(ch1_intf.channel_valid)
    115.   ,.slave1_margin(ch1_intf.slave_margin)
    116.   ,.channell_ready(ch1_intf.channel_ready)
    117.  
    118.   
    119.   ,.channel2_data(ch2_intf.channel_data)
    120.   ,.channel2_valid(ch2_intf.channel_valid)
    121.   ,.channel2_ready(ch2_intf.channel_ready)
    122.   ,.slave2_margin(ch2_intf.slave_margin)
    123.  
    124.   
    125.   ,.channel3_data(ch3_intf.channel_data)
    126.   ,.channel3_valid(ch3_intf.channel_valid)
    127.   ,.channel3_ready(ch3_intf.channel_ready)
    128.   ,.slave3_margin(ch3_intf.slave_margin)
    129.  
    130.   
    131.   ,.mcdt_data_output(mcdt_data_output)
    132.   ,.mcdt_valid(mcdt_valid)
    133.   ,.mcdt_id(mcdt_id)
    134. );
    135.  
    136.  
    137. //*****************clk和rstn******************************//
    138. task clk_gen(input int T);
    139.   clk <= 0;
    140.   forever begin
    141.     #(T/2) clk<= !clk;
    142.   end
    143. endtask
    144.  
    145. initial begin
    146.   clk_gen(10);
    147. end
    148.  
    149. task rstn_gen();
    150.   #10 rstn <= 0;
    151.   repeat(20) @(posedge clk);
    152.   rstn <= 1;
    153. endtask
    154.  
    155. initial begin
    156.   rstn_gen();
    157. end
    158.   
    159. //**************************************************//
    160. generator_chen ch1_gen;
    161. generator_chen ch2_gen;
    162. generator_chen ch3_gen;
    163. //将generator分成3份。分别对应mcdt的信号
    164. initiator_chen ch1_init;
    165. initiator_chen ch2_init;
    166. initiator_chen ch3_init;
    167. //将initiator分成3份
    168. //*******************以上不变*********************//
    169.  
    170. initial begin
    171. 	//命名和初始化3个通道,test里面的都可以删掉了
    172. 	ch1_init=new("ch1_init");
    173. 	ch2_init=new("ch2_init");
    174. 	ch3_init=new("ch3_init");
    175. 	ch1_gen=new(1);
    176. 	ch2_gen=new(2);
    177. 	ch3_gen=new(3);
    178. 	//接口给到initiator，连接了
    179. 	ch1_init.set_interface(ch1_intf);
    180. 	ch2_init.set_interface(ch2_intf);
    181. 	ch3_init.set_interface(ch3_intf);
    182. 	$display("********all of tests have been finished***********");
    183.     //basic_test();
    184. 	//burst_test();
    185. 	full_test();
    186. 	$finish();
    187. end
    188.  
    189.  
    190.  
    191.  
    192. //*****************************3个test**********************************//
    193.  
    194. //1. idle_cycle在1-3之间，每个通道发送200个数据，都完成后就结束
    195. task automatic basic_test();
    196.  
    197. //设置idle_cycle
    198. ch1_init.set_idle_cycle($urandom_range(1,3));
    199. ch2_init.set_idle_cycle($urandom_range(1,3));
    200. ch3_init.set_idle_cycle($urandom_range(1,3));
    201. $display("basic_test initialized components");
    202.  
    203. wait (rstn===1'b1);
    204. repeat(5) @(posedge clk);
    205. $display("basic_test started testing dut");
    206.  
    207. fork
    208. 	repeat(100) ch1_init.chnl_write(ch1_gen.get_trans());
    209. 	repeat(100) ch2_init.chnl_write(ch2_gen.get_trans());
    210. 	repeat(100) ch3_init.chnl_write(ch3_gen.get_trans());
    211. join
    212.  
    213. fork
    214. 	wait(ch1_init.intf.slave_margin=='hff);
    215. 	wait(ch2_init.intf.slave_margin=='hff);
    216. 	wait(ch3_init.intf.slave_margin=='hff);
    217. join
    218. $display("finished");
    219. endtask
    220.  
    221.  
    222. //2.idle为0，每个通道发送500个数据
    223. task automatic burst_test();
    224.  
    225. //设置idle_cycle
    226. ch1_init.set_idle_cycle(0);
    227. ch2_init.set_idle_cycle(0);
    228. ch3_init.set_idle_cycle(0);
    229. $display("burst_test initialized components");
    230. fork
    231. 	repeat(500) ch1_init.chnl_write(ch1_gen.get_trans());
    232. 	repeat(500) ch2_init.chnl_write(ch2_gen.get_trans());
    233. 	repeat(500) ch3_init.chnl_write(ch3_gen.get_trans());
    234. join
    235.  
    236. fork
    237. 	wait(ch1_init.intf.slave_margin=='hff);//256-200=56转换成十六进制?
    238. 	wait(ch2_init.intf.slave_margin=='hff);//但其实是说直到空了，也就是全部数据都读完
    239. 	wait(ch3_init.intf.slave_margin=='hff);
    240. join
    241. $display("finished");
    242.  
    243. endtask
    244.  
    245.  
    246. //3. 所有通道都装满的时候停止，不需要同时达到
    247. task automatic full_test();
    248. //设置idle_cycle
    249. ch1_init.set_idle_cycle(0);
    250. ch2_init.set_idle_cycle(0);
    251. ch3_init.set_idle_cycle(0);
    252. $display("full_test initialized components");
    253.  
    254. fork: fork_all_run
    255. 	forever ch1_init.chnl_write(ch1_gen.get_trans());
    256. 	forever ch2_init.chnl_write(ch2_gen.get_trans());
    257. 	forever ch3_init.chnl_write(ch3_gen.get_trans());
    258. join_none//这个fj执行的时候下面的fj也开始执行
    259. $display("running, waiting full");
    260. fork
    261. 	wait(ch1_init.intf.slave_margin=='h0);//满了就执行下面的，不用等其他的满
    262. 	wait(ch2_init.intf.slave_margin=='h0);
    263. 	wait(ch3_init.intf.slave_margin=='h0);
    264. join
    265. $display("full");
    266. disable fork_all_run;//让none那个停下来，别写入数据了
    267.  
    268. fork
    269. 	ch1_init.channel_idle();
    270. 	ch2_init.channel_idle();
    271. 	ch3_init.channel_idle();
    272. join
    273. $display("waiting all data transferred");
    274.  
    275. $display("finished");
    276.  
    277. endtask
    278.  
    279.  
    280. endmodule

     编译和仿真都可以了。

     复习一下package的知识点

    CSDNhttps://mp.csdn.net/mp_blog/creation/editor/125289909要求4是加入包以及用类的继承来做3个test

    tb4改造思路：

    • 所有的class都封装在package里面，包括trans, gen,init,agent,root_test,basic_test,burst_test, full_test
    • trans, initiator, generator不用变动
    • agent中包含init和gen的句柄，标志数据个数的变量ntrans，通过将接口代入set_interface和initiator连接，将ntrans作为参数和generator连接，分别是发送和产生数据。
    • 将3个test中相同的部分放到root_test中，包括设置数据个数ntrans和名字name，声明3个agent句柄，例化每个agent，运行起来run，需要将接口连接到3个句柄上
    • 3个test作为子类继承root_test
    • 3个test只需要设置ntrans和name和idle_cycle即可，并分别给到父类中的new函数。
    • 第3个test还是需要用fork_join_none继续写
    • 以上就是包的内容
    • 在tb这个module中，依然是例化mcdt+产生时钟信号+产生复位信号+例化接口。
    • 在tb这个module中，要先用import引入所有类（module是硬件盒子），然后才能声明3个test的句柄，并例化。然后将3个接口作为参数给到3个句柄中的set_interface，由于3个test中没有这个函数，所以往父类root_test中寻找，给到agent的set_interface，再给到initiator的set_interface，由此完成了信号的层层传递。
    • 最后调用3个句柄中的run，也就是各自test中的run，跑起来了

    tb4结构示意图

     

     tb4代码

    1. `timescale 1ns/1ps
    2. //*********************用包package来改造**************************//
    3.  
    4. //**********************接口和时钟块不变****************************//
    5. interface interface_chen (input clk, input rstn);
    6.  
    7. logic [31:0] channel_data;
    8. logic        channel_valid;
    9. logic        channel_ready;
    10. logic [ 7:0] slave_margin;
    11.  
    12. clocking drv_clk @(posedge clk);
    13. 	default input #1ns output #1ns;
    14. 	input  channel_ready, slave_margin;//采样
    15. 	output channel_data, channel_valid;//驱动
    16. endclocking 
    17.  
    18. endinterface 
    19. //**************************************************//
    20. package ch_pkg;
    21. //**************************************************//
    22. class ch_trans;
    23. 	int data;
    24. 	int id;
    25. 	int num;
    26. endclass
    27. //**************************************************//
    28. class initiator_chen;
    29. virtual interface_chen intf;//virtual表示在子类中会被调用到，声明类的成员变量接口指针必须用virtual
    30.  
    31. local int idle_cycle;
    32. local string name;
    33.  
    34. function new(string name="initiator_chen");//这里其实就是初始化
    35. 	this.name=name;
    36. 	this.idle_cycle=1;
    37. endfunction
    38.  
    39. //类里面所有变量都是动态变量，不需要加automatic了
    40. function void set_idle_cycle(int n);
    41. 	this.idle_cycle=n;
    42. endfunction
    43.  
    44. function void set_name(string s);
    45. 	this.name=s;
    46. endfunction
    47. //这里替代的是三个接口的例化
    48. function void set_interface(virtual interface_chen intf);
    49. 	if(intf==null)
    50. 		$error("null, need to be intantiated.");
    51. 	else this.intf=intf;
    52. endfunction
    53.  
    54. task chnl_write (input ch_trans t);//数据封装在ch_trans里面，这个类的句柄声明为t
    55. 	@(posedge intf.clk);
    56. 	intf.drv_clk.channel_valid<=1'b1;
    57. 	intf.drv_clk.channel_data<=t.data;//data要加t.引用
    58. 	@(negedge intf.clk);
    59. 	wait(intf.channel_ready==1'b1);
    60. 	$display("%t channel initial [%s] sent data %x", $time, name, t.data);
    61. 	repeat (this.idle_cycle) channel_idle();		
    62. endtask
    63.  
    64. task channel_idle();
    65. 	@(posedge intf.clk);
    66. 	intf.drv_clk.channel_valid<=1'b0;
    67. 	intf.drv_clk.channel_data<=1'b0;
    68. endtask
    69.  
    70.  
    71. endclass 
    72. //**************************************************//
    73. class generator_chen;
    74. ch_trans trans[$];//存放ch_trans句柄的队列
    75. ch_trans t;//声明句柄
    76. int num;
    77. int id;
    78.  
    79. function new(int n);//替代原来的初始化函数，完成初始化
    80. 	this.id=n;
    81. 	this.num=0;
    82. endfunction 
    83.  
    84. //替代生成数据的func get_data
    85. function ch_trans get_trans();//类的句柄函数
    86. 	ch_trans t=new();//对类进行例化，创建一个名为t的ch_trans对象
    87. 	t.data='h00C0_00000+(this.id<<16)+this.num;
    88. 	t.id=this.id;//把gen的id赋给ch_trans的id
    89. 	t.num=this.num;
    90. 	this.num++;
    91. 	this.trans.push_back(t);
    92. 	return t;
    93. endfunction
    94.  
    95. endclass
    96. //**************************************************//
    97. class ch_agent;
    98. 	generator_chen gen;
    99. 	initiator_chen init;
    100. 	local int ntrans;
    101. 	virtual interface_chen aintf;
    102. 	
    103. 	function new(string name="ch_agent", int id=0, int ntrans=1);
    104. 		this.gen=new(id);
    105. 		this.init=new(name);
    106. 		this.ntrans=ntrans;
    107. 	endfunction
    108. 	
    109. 	function void set_n_trans(int n);
    110. 		this.ntrans=n;
    111. 	endfunction
    112. 	
    113. 	function void set_interface(virtual interface_chen aintf);
    114. 		this.aintf=aintf;
    115. 		init.set_interface(aintf);
    116. 	endfunction
    117. 	
    118. 	task run();
    119. 		repeat(this.ntrans) this.init.chnl_write(this.gen.get_trans);
    120. 		this.init.channel_idle();
    121. 	endtask
    122. endclass 
    123. //**************************************************//
    124. class root_test;
    125. 	ch_agent agent[3];//声明3个agent数组
    126. 	protected string name;
    127. 	
    128. 	function new(int ntrans=100, string name ="ch_root_test");
    129. 	foreach(agent[i]) begin
    130. 		this.agent[i]=new($sformatf("ch_agent%0d",i),i,ntrans);
    131. 	end
    132. 	this.name=name;
    133. 	$display("%s instantiate objects",this.name);
    134. 	endfunction
    135. 	
    136. 	task run();
    137. 		$display("%s started testing dut", this.name);
    138. 		fork
    139. 			agent[0].run();
    140. 			agent[1].run();
    141. 			agent[2].run();
    142. 		join 
    143. 		$display("%s waiting", this.name);
    144. 		fork
    145. 			wait(agent[0].aintf.slave_margin=='hff);
    146. 			wait(agent[1].aintf.slave_margin=='hff);
    147. 			wait(agent[2].aintf.slave_margin=='hff);
    148. 		join
    149. 		$display("%s finished all data", this.name);
    150. 	endtask
    151. 	
    152. 	function void set_interface(virtual interface_chen ch1_aintf
    153. 							   ,virtual interface_chen ch2_aintf
    154. 							   ,virtual interface_chen ch3_aintf);
    155. 		agent[0].set_interface(ch1_aintf);
    156. 		agent[1].set_interface(ch2_aintf);
    157. 		agent[2].set_interface(ch3_aintf);
    158. 	endfunction
    159. endclass
    160.  
    161. class basic_test extends root_test;
    162. function new(int ntrans=200, string name="basic_test");
    163. 	super.new(ntrans, name);
    164. 	foreach(agent[i]) begin
    165. 		this.agent[i].init.set_idle_cycle($urandom_range(1,3));
    166. 	end
    167. 	$display("%s configured objects", this.name);
    168. endfunction
    169. endclass: basic_test
    170.  
    171. class burst_test extends root_test;
    172. function new(int ntrans=500, string name="burst_test");
    173. 	super.new(ntrans,name);
    174. 	foreach(agent[i]) begin
    175. 		this.agent[i].init.set_idle_cycle(0);
    176. 	end
    177. 	$display("%s configured objects", this.name);
    178. endfunction
    179. endclass: burst_test
    180.  
    181. class full_test extends root_test;
    182. function new(int ntrans=1000000, string name="full_test");
    183. 	super.new(ntrans, name);
    184. 	foreach(agent[i]) begin
    185. 		this.agent[i].init.set_idle_cycle(0);
    186. 	end
    187. 	$display("%s configured objects", this.name);
    188. endfunction
    189.  
    190. task run();
    191. 	$display("%s started testing dut", this.name);
    192. 	fork :fork_all_run
    193. 		agent[0].run();
    194. 		agent[1].run();
    195. 		agent[2].run();
    196. 	join_none
    197. 	
    198. 	$display("%s 3agents running, waiting full", this.name);
    199. 	
    200. 	fork
    201. 		wait(agent[0].aintf.slave_margin=='h0);
    202. 		wait(agent[1].aintf.slave_margin=='h0);
    203. 		wait(agent[2].aintf.slave_margin=='h0);
    204. 	join
    205. 	
    206. 	$display("%s full, stop", this.name);
    207. 	disable fork_all_run;
    208. 	$display("%s all idle", this.name);
    209. 	
    210. 	fork
    211. 		agent[0].init.channel_idle();
    212. 		agent[1].init.channel_idle();
    213. 		agent[1].init.channel_idle();
    214. 	join
    215. 	
    216. 	$display("%s waiting", this.name);
    217. 	
    218. 	fork
    219. 		wait(agent[0].aintf.slave_margin=='hff);
    220. 		wait(agent[1].aintf.slave_margin=='hff);
    221. 		wait(agent[2].aintf.slave_margin=='hff);
    222. 	join
    223. 	
    224. 	$display("%s finished all data", this.name);
    225. 	
    226. endtask
    227.  
    228. endclass: full_test
    229.  
    230. endpackage :ch_pkg
    231. //**************************************************//
    232. module tb1_chen();//
    233.  
    234. logic          clk;
    235. logic          rstn;
    236. logic [31:0]		mcdt_data_output;
    237. logic				mcdt_valid;
    238. logic [1:0]			mcdt_id;
    239.  
    240.  
    241. mcdt_chen dut(//括号里面的信号变成接口里面的
    242.    .clk(clk)
    243.   ,.rstn(rstn)
    244.   
    245.   ,.channel1_data(ch1_intf.channel_data)//信号改为接口中的名称
    246.   ,.channel1_valid(ch1_intf.channel_valid)
    247.   ,.slave1_margin(ch1_intf.slave_margin)
    248.   ,.channell_ready(ch1_intf.channel_ready)
    249.  
    250.   
    251.   ,.channel2_data(ch2_intf.channel_data)
    252.   ,.channel2_valid(ch2_intf.channel_valid)
    253.   ,.channel2_ready(ch2_intf.channel_ready)
    254.   ,.slave2_margin(ch2_intf.slave_margin)
    255.  
    256.   
    257.   ,.channel3_data(ch3_intf.channel_data)
    258.   ,.channel3_valid(ch3_intf.channel_valid)
    259.   ,.channel3_ready(ch3_intf.channel_ready)
    260.   ,.slave3_margin(ch3_intf.slave_margin)
    261.  
    262.   
    263.   ,.mcdt_data_output(mcdt_data_output)
    264.   ,.mcdt_valid(mcdt_valid)
    265.   ,.mcdt_id(mcdt_id)
    266. );
    267.  
    268.  
    269. //*****************clk和rstn******************************//
    270. task clk_gen(input int T);
    271.   clk <= 0;
    272.   forever begin
    273.     #(T/2) clk<= !clk;
    274.   end
    275. endtask
    276.  
    277. initial begin
    278.   clk_gen(10);
    279. end
    280.  
    281. task rstn_gen();
    282.   #10 rstn <= 0;
    283.   repeat(20) @(posedge clk);
    284.   rstn <= 1;
    285. endtask
    286.  
    287. initial begin
    288.   rstn_gen();
    289. end
    290.  
    291. import ch_pkg::*;//引入包中所有的类 
    292.  
    293. //**************************************************//
    294. basic_test b1;//句柄
    295. burst_test b2;
    296. full_test  b3;
    297.  
    298.  
    299. //**************mcdt-接口-generator************************//
    300. interface_chen ch1_intf(.*);
    301. interface_chen ch2_intf(.*);
    302. interface_chen ch3_intf(.*);
    303. //将接口分成3份。分别对应mcdt的信号
    304.  
    305.  
    306. initial begin
    307. 	b1=new();
    308. 	b2=new();
    309. 	b3=new();
    310. 	//对3个test例化，创建对象
    311. 	b1.set_interface(ch1_intf, ch2_intf, ch3_intf);
    312. 	b2.set_interface(ch1_intf, ch2_intf, ch3_intf);
    313. 	b3.set_interface(ch1_intf, ch2_intf, ch3_intf);
    314. 	
    315. 	b1.run();
    316. 	b2.run();
    317. 	b3.run();
    318. 	  
    319. 	$display("********all of tests have been finished***********");
    320. 	$finish();
    321. end
    322.  
    323.  
    324. endmodule

     basic_test

     

     burst_test

     

     full_test

    对这个单独测试，里面agent[ ]有个写成011，需要改成012.

     

     先装满，后清空

     

  • 相关阅读:
    第九章：最新版零基础学习 PYTHON 教程—Python 元组（第五节 -清除元组的5种方式方法）
    在C++中什么是异常处理以及如何使用try-catch块
    【Quark RISC-V】流水线CPU设计（3）数据相关与流水线冒险
    基于springboot的通知反馈系统
    DockerFile的使用
    新型智慧公厕建设：引领公厕行业的未来！
    Selenium模拟浏览器访问
    掌动智能：UI自动化测试工具产品功能和优势
    Go语言结构体
    【考研数学】线性代数第六章 —— 二次型（3，正定矩阵与正定二次型）
  • 原文地址：https://blog.csdn.net/weixin_39668316/article/details/125514830